[PATCH v5 26/27] dpkg-base: Add devshell target

[Jan Kiszka <jan.kiszka@siemens.com>]

From: Jan Kiszka <jan.kiszka@siemens.com>

Using the imported OE core services, this adds devshell support for dpkg
package builds. The target is put after do_install_builddeps where
available, otherwise do_prepare_build.

Signed-off-by: Jan Kiszka <jan.kiszka@siemens.com>
---
 doc/user_manual.md                         |  8 ++++++++
 meta/classes/dpkg-base.bbclass             | 26 +++++++++++++++++++++++++-
 meta/classes/dpkg.bbclass                  |  2 ++
 meta/recipes-kernel/linux/linux-custom.inc |  2 ++
 4 files changed, 37 insertions(+), 1 deletion(-)

diff --git a/doc/user_manual.md b/doc/user_manual.md
index 47f0dd5..c2657da 100644
--- a/doc/user_manual.md
+++ b/doc/user_manual.md
@@ -682,6 +682,14 @@ Debian cross-compilation works out of the box starting from Debian stretch distr
  - qemuarm64-buster (for host >= buster)
 
 
+## Examining and debugging package generation inside their buildchroot
+
+Just like OpenEmbedded, Isar supports a devshell target for all dpkg package
+recipes. This target opens a terminal inside the buildchroot that runs the
+package build. To invoke it, just call
+`bitbake multiconfig:${MACHINE}-${DISTRO}:<package_name> -c devshell`.
+
+
 ## Create an ISAR SDK root filesystem
 
 ### Motivation
diff --git a/meta/classes/dpkg-base.bbclass b/meta/classes/dpkg-base.bbclass
index fa904b8..2e8a0d1 100644
--- a/meta/classes/dpkg-base.bbclass
+++ b/meta/classes/dpkg-base.bbclass
@@ -1,10 +1,11 @@
 # This software is a part of ISAR.
-# Copyright (C) 2017-2018 Siemens AG
+# Copyright (C) 2017-2019 Siemens AG
 #
 # SPDX-License-Identifier: MIT
 
 inherit buildchroot
 inherit debianize
+inherit terminal
 
 DEPENDS ?= ""
 
@@ -136,3 +137,26 @@ addtask deploy_deb after do_dpkg_build before do_build
 do_deploy_deb[lockfiles] = "${REPO_ISAR_DIR}/isar.lock"
 do_deploy_deb[depends] = "isar-apt:do_cache_config"
 do_deploy_deb[dirs] = "${S}"
+
+python do_devshell() {
+    import sys
+
+    oe_lib_path = os.path.join(d.getVar('LAYERDIR_core'), 'lib')
+    sys.path.insert(0, oe_lib_path)
+
+    bb.build.exec_func('dpkg_do_mounts', d);
+
+    bb.utils.export_proxies(d)
+
+    buildchroot = d.getVar('BUILDCHROOT_DIR')
+    pp_pps = os.path.join(d.getVar('PP'), d.getVar('PPS'))
+    termcmd = "sudo -E chroot {0} sh -c 'cd {1}; $SHELL -i'"
+    oe_terminal(termcmd.format(buildchroot, pp_pps), "Isar devshell", d)
+
+    bb.build.exec_func('dpkg_undo_mounts', d);
+}
+
+addtask devshell after do_prepare_build
+DEVSHELL_STARTDIR ?= "${S}"
+do_devshell[dirs] = "${DEVSHELL_STARTDIR}"
+do_devshell[nostamp] = "1"
diff --git a/meta/classes/dpkg.bbclass b/meta/classes/dpkg.bbclass
index f5396cb..19d77a2 100644
--- a/meta/classes/dpkg.bbclass
+++ b/meta/classes/dpkg.bbclass
@@ -15,6 +15,8 @@ addtask install_builddeps after do_prepare_build before do_dpkg_build
 # apt and reprepro may not run in parallel, acquire the Isar lock
 do_install_builddeps[lockfiles] += "${REPO_ISAR_DIR}/isar.lock"
 
+addtask devshell after do_install_builddeps
+
 # Build package from sources using build script
 dpkg_runbuild() {
     E="${@ bb.utils.export_proxies(d)}"
diff --git a/meta/recipes-kernel/linux/linux-custom.inc b/meta/recipes-kernel/linux/linux-custom.inc
index e75eed1..8ff3836 100644
--- a/meta/recipes-kernel/linux/linux-custom.inc
+++ b/meta/recipes-kernel/linux/linux-custom.inc
@@ -47,6 +47,8 @@ addtask install_builddeps after do_prepare_build before do_dpkg_build
 # apt and reprepro may not run in parallel, acquire the Isar lock
 do_install_builddeps[lockfiles] += "${REPO_ISAR_DIR}/isar.lock"
 
+addtask devshell after do_install_builddeps
+
 dpkg_runbuild() {
 	chmod +x ${WORKDIR}/build-kernel.sh
 	if [ -n "${KERNEL_DEFCONFIG}" ]; then
-- 
2.16.4