[PATCH] wic-img: handle variables in .wks files

[Cedric Hombourger <Cedric_Hombourger@mentor.com>]

Isar will now generate .wks from user-specified templates with variables
such as $ROOTFS_TYPE or $ROOTFS_SIZE replaced with their values. Custom
variables may be substituted by adding them to WKSVARS (WKSVAR += FOO)

Signed-off-by: Cedric Hombourger <Cedric_Hombourger@mentor.com>
---
 doc/user_manual.md           |  2 ++
 meta/classes/wic-img.bbclass | 31 ++++++++++++++++++++++++++++++-
 2 files changed, 32 insertions(+), 1 deletion(-)

diff --git a/doc/user_manual.md b/doc/user_manual.md
index ebc31c6..ea3b4bd 100644
--- a/doc/user_manual.md
+++ b/doc/user_manual.md
@@ -197,6 +197,8 @@ A bootable disk image is generated if you set IMAGE_TYPE to 'wic-img'. Behind th
  $ bitbake multiconfig:qemuamd64-stretch:isar-image-base
 ```
 
+Note: `.wks` files may use the ROOTFS_SIZE and ROOTFS_TYPE variables (as well as any other bitbake variables added to WKSVARS).
+
 In order to run the EFI images with `qemu`, an EFI firmware is required and available at the following address:
 https://github.com/tianocore/edk2/tree/3858b4a1ff09d3243fea8d07bd135478237cb8f7
 
diff --git a/meta/classes/wic-img.bbclass b/meta/classes/wic-img.bbclass
index 76602d8..16bbc53 100644
--- a/meta/classes/wic-img.bbclass
+++ b/meta/classes/wic-img.bbclass
@@ -81,6 +81,32 @@ addtask do_rootfs_wicenv after do_copy_boot_files before do_wic_image
 do_rootfs_wicenv[vardeps] += "${WICVARS}"
 do_rootfs_wicenv[prefuncs] = 'set_image_size'
 
+WKSVARS += "ROOTFS_SIZE ROOTFS_TYPE"
+
+python do_rootfs_wksenv () {
+    wksvars = d.getVar('WKSVARS', True)
+    if not wksvars:
+        return
+
+    stdir = d.getVar('STAGING_DIR', True)
+    outdir = os.path.join(stdir, d.getVar('MACHINE', True), 'imgdata')
+    bb.utils.mkdirhier(outdir)
+    basename = d.getVar('IMAGE_BASENAME', True)
+    with open(os.path.join(outdir, basename) + '-wks.sh', 'w') as envf:
+        for var in wksvars.split():
+            value = d.getVar(var, True)
+            if value:
+                envf.write('%s="%s" \\\n' % (var, value.strip()))
+        envf.write("envsubst '")
+        for var in wksvars.split():
+            envf.write('$%s ' % var)
+        envf.write("'\n")
+}
+
+addtask do_rootfs_wksenv after do_rootfs_wicenv before do_wic_image
+do_rootfs_wksenv[vardeps] += "${WKSVARS}"
+do_rootfs_wksenv[prefuncs] = 'set_image_size'
+
 WIC_IMAGE_FILE ="${DEPLOY_DIR_IMAGE}/${IMAGE_FULLNAME}.wic.img"
 
 do_build[stamp-extra-info] = "${DISTRO}-${DISTRO_ARCH}"
@@ -99,8 +125,11 @@ do_wic_image() {
     export BUILDDIR=${BUILDDIR}
     export MTOOLS_SKIP_CHECK=1
 
+    /bin/sh ${STAGING_DIR}/${MACHINE}/imgdata/${IMAGE_BASENAME}-wks.sh \
+        <${WKS_FULL_PATH} >${BUILDCHROOT_DIR}/tmp/${IMAGE_FULLNAME}.wks
+
     sudo -E chroot ${BUILDCHROOT_DIR} \
-        ${ISARROOT}/scripts/wic create ${WKS_FULL_PATH} \
+        ${ISARROOT}/scripts/wic create /tmp/${IMAGE_FULLNAME}.wks \
             --vars "${STAGING_DIR}/${MACHINE}/imgdata/" \
             -o /tmp/${IMAGE_FULLNAME}.wic/ \
             -e ${IMAGE_BASENAME} ${WIC_CREATE_EXTRA_ARGS}
-- 
2.11.0