[PATCH v2 6/6] recipes-app/example-raw: add an example on how to use dpkg-raw

[Henning Schild <henning.schild@siemens.com>]

Issue:
It might not be clear to a user how to make use of the class
dpkg-raw.

Change:
Add an example that demonstrates some features.

Impact:
This patch does not change the behaviour of Isar. It addresses the issue
partially, documentation would also be useful.

Signed-off-by: Henning Schild <henning.schild@siemens.com>
---
 .../recipes-app/example-raw/example-raw_0.1.bb     | 35 ++++++++++++++++++++++
 meta-isar/recipes-app/example-raw/files/README     |  1 +
 meta-isar/recipes-app/example-raw/files/postinst   | 16 ++++++++++
 3 files changed, 52 insertions(+)
 create mode 100644 meta-isar/recipes-app/example-raw/example-raw_0.1.bb
 create mode 100644 meta-isar/recipes-app/example-raw/files/README
 create mode 100644 meta-isar/recipes-app/example-raw/files/postinst

diff --git a/meta-isar/recipes-app/example-raw/example-raw_0.1.bb b/meta-isar/recipes-app/example-raw/example-raw_0.1.bb
new file mode 100644
index 0000000..d548465
--- /dev/null
+++ b/meta-isar/recipes-app/example-raw/example-raw_0.1.bb
@@ -0,0 +1,35 @@
+# Sample application using dpkg-raw, which turns a folder (${D}) of
+# files into a .deb 
+#
+# This software is a part of ISAR.
+
+DESCRIPTION = "Sample application for ISAR"
+MAINTAINER = "Your name here <you@domain.com>"
+DEBIAN_DEPENDS = "apt"
+
+SRC_URI = "file://README \
+	   file://postinst"
+
+inherit dpkg-raw
+
+do_populate_package() {
+	bbnote "Creating ${PN} binary"
+	echo "#!/bin/sh" > ${WORKDIR}/${PN}
+	echo "echo Hello ISAR! ${PN}_${PV}" >> ${WORKDIR}/${PN}
+
+	bbnote "Putting ${PN} into package"
+	install -v -d ${D}/usr/local/bin/
+	install -v -m 755 ${WORKDIR}/${PN} ${D}/usr/local/bin/${PN}
+
+	bbnote "Now copy ${FILESDIR}/README into package"
+	install -v -d ${D}/usr/local/doc/
+	install -v -m 644 ${WORKDIR}/README ${D}/usr/local/doc/README-${P}
+
+	bbnote "Now for a debian hook, see dpkg-deb"
+	install -v -m 755 ${WORKDIR}/postinst ${D}/DEBIAN/postinst
+
+	bbnote "Now for a fake config file"
+	echo "# empty config file" > ${WORKDIR}/${PN}.conf
+	install -v -d ${D}/usr/local/etc/
+	install -v -m 644 ${WORKDIR}/${PN}.conf ${D}/usr/local/etc/${PN}.conf
+}
diff --git a/meta-isar/recipes-app/example-raw/files/README b/meta-isar/recipes-app/example-raw/files/README
new file mode 100644
index 0000000..6e2ce0f
--- /dev/null
+++ b/meta-isar/recipes-app/example-raw/files/README
@@ -0,0 +1 @@
+This is an example file that we get from FILESDIR in recipe.
diff --git a/meta-isar/recipes-app/example-raw/files/postinst b/meta-isar/recipes-app/example-raw/files/postinst
new file mode 100644
index 0000000..a28afa3
--- /dev/null
+++ b/meta-isar/recipes-app/example-raw/files/postinst
@@ -0,0 +1,16 @@
+#!/bin/sh
+
+set -e
+
+if ! getent group isar >/dev/null; then
+	addgroup --quiet --system isar
+fi
+
+if ! getent passwd isar >/dev/null; then
+	useradd --system --gid isar --create-home \
+		--home /var/lib/isar --no-user-group \
+		--comment "My isar user" \
+		isar
+fi
+
+chown -R isar:isar /var/lib/isar
-- 
2.13.5