[PATCH v5 2/5] meta/isar-bootstrap-helper.bbclass: handle rfs customization centrally

[claudius.heine.ext@siemens.com]

From: Claudius Heine <ch@denx.de>

This patch introduces the 'isar-bootstrap-helper' bitbake class to
support recipes that use the basic root file system created by
isar-bootstrap.

In this patch the function 'setup_root_file_system' is defined that
allows to copy the root file system to the directory specified in the
first parameter and installs additional packages specified by the
next parameters. It also adds the local 'isar-apt' repo to the apt
configuration and fetches its index.

Signed-off-by: Claudius Heine <ch@denx.de>
---
 meta/classes/isar-bootstrap-helper.bbclass | 39 ++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 meta/classes/isar-bootstrap-helper.bbclass

diff --git a/meta/classes/isar-bootstrap-helper.bbclass b/meta/classes/isar-bootstrap-helper.bbclass
new file mode 100644
index 0000000..a06116d
--- /dev/null
+++ b/meta/classes/isar-bootstrap-helper.bbclass
@@ -0,0 +1,39 @@
+# Helper functions for using isar-bootstrap
+#
+# This software is a part of ISAR.
+# Copyright (c) Siemens AG, 2018
+#
+# SPDX-License-Identifier: MIT
+
+setup_root_file_system() {
+    ROOTFSDIR="$1"
+    shift
+    PACKAGES="$@"
+
+    sudo cp -Trpfx \
+        "${DEPLOY_DIR_IMAGE}/isar-bootstrap-${DISTRO}-${DISTRO_ARCH}/" \
+        "$ROOTFSDIR"
+
+    echo "deb file:///isar-apt ${DEBDISTRONAME} main" | \
+        sudo tee "$ROOTFSDIR/etc/apt/sources.list.d/isar-apt.list" >/dev/null
+
+    echo "Package: *\nPin: release n=${DEBDISTRONAME}\nPin-Priority: 1000" | \
+        sudo tee "$ROOTFSDIR/etc/apt/preferences.d/isar" >/dev/null
+
+    sudo mount --bind ${DEPLOY_DIR_APT}/${DISTRO} $ROOTFSDIR/isar-apt
+    sudo mount -t devtmpfs -o mode=0755,nosuid devtmpfs $ROOTFSDIR/dev
+    sudo mount -t proc none $ROOTFSDIR/proc
+
+    # Install packages:
+    E="${@ bb.utils.export_proxies(d)}"
+    export DEBIAN_FRONTEND=noninteractive
+    sudo -E chroot "$ROOTFSDIR" /usr/bin/apt-get update \
+        -o Dir::Etc::sourcelist="sources.list.d/isar-apt.list" \
+        -o Dir::Etc::sourceparts="-" \
+        -o APT::Get::List-Cleanup="0"
+    sudo -E chroot "$ROOTFSDIR" \
+        /usr/bin/apt-get install -y \
+            --allow-unauthenticated \
+            -o Debug::pkgProblemResolver=yes \
+        $PACKAGES
+}
-- 
2.16.3