[RFC PATCH 3/6] sdkchroot: Added recipe-devel to create SDK root filesystem

["Maxim Yu. Osipov" <mosipov@ilbers.de>]

Building applications for targets in ISAR takes a lot of time as
they are built under QEMU. SDK providing crossbuild environment
will help to solve this problem.

Create SDK root file system for host with installed cross-toolchain for
target architecture and ability to install already prebuilt target binary
artifacts. Developer chroots to sdk rootfs and develops applications
for target platform.

Signed-off-by: Maxim Yu. Osipov <mosipov@ilbers.de>
---
 .../sdkchroot/files/configscript.sh                | 14 +++++
 meta/recipes-devtools/sdkchroot/sdkchroot.bb       | 59 ++++++++++++++++++++++
 2 files changed, 73 insertions(+)
 create mode 100644 meta/recipes-devtools/sdkchroot/files/configscript.sh
 create mode 100644 meta/recipes-devtools/sdkchroot/sdkchroot.bb

diff --git a/meta/recipes-devtools/sdkchroot/files/configscript.sh b/meta/recipes-devtools/sdkchroot/files/configscript.sh
new file mode 100644
index 0000000..62c1cf0
--- /dev/null
+++ b/meta/recipes-devtools/sdkchroot/files/configscript.sh
@@ -0,0 +1,14 @@
+#!/bin/sh
+#
+# This software is a part of ISAR.
+# Copyright (C) 2015-2018 ilbers GmbH
+
+set -e
+
+debconf-set-selections <<END
+locales locales/locales_to_be_generated multiselect en_US.UTF-8 UTF-8
+locales locales/default_environment_locale select en_US.UTF-8
+END
+
+dpkg --add-architecture $1
+apt-get update --yes -o Debug::pkgProblemResolver=yes
diff --git a/meta/recipes-devtools/sdkchroot/sdkchroot.bb b/meta/recipes-devtools/sdkchroot/sdkchroot.bb
new file mode 100644
index 0000000..d884d80
--- /dev/null
+++ b/meta/recipes-devtools/sdkchroot/sdkchroot.bb
@@ -0,0 +1,59 @@
+# SDK Root filesystem
+#
+# This software is a part of ISAR.
+# Copyright (C) 2015-2018 ilbers GmbH
+
+DESCRIPTION = "Isar SDK Root filesystem"
+
+LICENSE = "gpl-2.0"
+LIC_FILES_CHKSUM = "file://${LAYERDIR_isar}/licenses/COPYING.GPLv2;md5=751419260aa954499f7abaabaa882bbe"
+
+FILESPATH_prepend := "${THISDIR}/files:"
+SRC_URI := "file://configscript.sh"
+PV = "1.0"
+
+inherit isar-bootstrap-helper
+
+def get_deb_host_arch():
+    import subprocess
+    arch =  subprocess.check_output(['dpkg-architecture', '-q', 'DEB_HOST_ARCH'], universal_newlines=True)
+    return str.splitlines(arch)[0]
+
+#SDK Debian Distribution
+DISTRO_HOST ?= "debian-stretch"
+#Determine SDK host architecture if not explicitly set
+DISTRO_HOST_ARCH ?= "${@get_deb_host_arch()}"
+
+
+SDKCHROOT_PREINSTALL := "crossbuild-essential-${DISTRO_ARCH} \
+                           debhelper \
+                           autotools-dev \
+                           dpkg \
+                           locales \
+                           docbook-to-man \
+                           apt \
+                           automake \
+                           devscripts \
+                           equivs"
+
+WORKDIR := "${TMPDIR}/work/${DISTRO}-${DISTRO_ARCH}/${PN}"
+SDKCHROOT_DIR := "${WORKDIR}/rootfs"
+
+do_build[stamp-extra-info] = "${DISTRO_HOST}-${DISTRO_HOST_ARCH}"
+do_build[root_cleandirs] = "${SDKCHROOT_DIR} \
+                            ${SDKCHROOT_DIR}/isar-apt"
+
+do_build[depends] = "isar-apt:do_cache_config isar-bootstrap-host:do_deploy"
+
+do_build() {
+
+    if [ ${DISTRO_HOST} != "debian-stretch" ]; then
+         bbfatal "SDK doesn't support ${DISTRO_HOST}"
+    fi
+
+    setup_host_root_file_system --copyrepo "${SDKCHROOT_DIR}" ${SDKCHROOT_PREINSTALL}
+
+    # Configure root filesystem
+    sudo install -m 755 ${WORKDIR}/configscript.sh ${SDKCHROOT_DIR}
+    sudo chroot ${SDKCHROOT_DIR} /configscript.sh  ${DISTRO_ARCH}
+}
-- 
2.11.0