[PATCH v2 1/3] meta/support: Generate a custom initramfs

["Q. Gylstorff" <Quirin.Gylstorff@siemens.com>]

From: Quirin Gylstorff <quirin.gylstorff@siemens.com>

This package sets the Parameters for mkinitramfs/update-intramfs
before it regenerates the initrd.img of debian with a modified version.

Use cases are the remove unnecessary kernel modules to reduce the
size of the initrd by using the parameters:
```
INITRAMFS_MODULES = "list"
INITRAMFS_MODULE_LIST += "ext4"
```

Set the boot root during the initrd generation by setting `INITRAMFS_ROOT`.

see also man pages of mkinitramfs and initramfs.conf.

Signed-off-by: Quirin Gylstorff <quirin.gylstorff@siemens.com>
---
 meta/classes/initramfs.bbclass                | 44 +++++++++++++++++++
 .../initramfs-config/files/control.tmpl       | 12 +++++
 .../initramfs-config/files/postinst.tmpl      | 28 ++++++++++++
 .../initramfs-config/initramfs-config_0.1.bb  | 30 +++++++++++++
 4 files changed, 114 insertions(+)
 create mode 100644 meta/classes/initramfs.bbclass
 create mode 100644 meta/recipes-support/initramfs-config/files/control.tmpl
 create mode 100644 meta/recipes-support/initramfs-config/files/postinst.tmpl
 create mode 100644 meta/recipes-support/initramfs-config/initramfs-config_0.1.bb

diff --git a/meta/classes/initramfs.bbclass b/meta/classes/initramfs.bbclass
new file mode 100644
index 0000000..0cc91c2
--- /dev/null
+++ b/meta/classes/initramfs.bbclass
@@ -0,0 +1,44 @@
+# This software is a part of ISAR.
+# Copyright (C) 2020 Siemens AG
+#
+# SPDX-License-Identifier: MIT
+
+INITRAMFS_MODULES ?= "most"
+INITRAMFS_BUSYBOX ?= "auto"
+INITRAMFS_COMPRESS ?= "gzip"
+INITRAMFS_KEYMAP ?= "n"
+INITRAMFS_NET_DEVICE ?= ""
+INITRAMFS_NFSROOT ?= "auto"
+INITRAMFS_RUNSIZE ?= "10%"
+INITRAMFS_ROOT ?= ""
+INITRAMFS_MODULE_LIST ?= ""
+update_initramfs_modules() {
+   for modname in ${INITRAMFS_MODULE_LIST}; do
+     sudo -E tee --append '${ROOTFSDIR}/etc/initramfs-tools/modules' << EOF
+${modname}
+EOF
+   done
+}
+update_initramfs_config() {
+    sudo -E tee ${ROOTFSDIR}/etc/initramfs-tools/initramfs.conf << EOF
+MODULES=${INITRAMFS_MODULES}
+BUSYBOX=${INITRAMFS_BUSYBOX}
+COMPRESS=${INITRAMFS_COMPRESS}
+KEYMAP=${INITRAMFS_KEYMAP}
+DEVICE=${INITRAMFS_NET_DEVICE}
+NFSROOT=${INITRAMFS_NFSROOT}
+RUNSIZE=${INITRAMFS_RUNSIZE}
+ROOT=${INITRAMFS_ROOT}
+EOF
+}
+
+do_update_initramfs() {
+  update_initramfs_modules
+  update_initramfs_config
+  export KERNEL_VERSION=$(ls ${ROOTFSDIR}/lib/modules)
+  bbplain kernel_version: ${KERNEL_VERSION}
+  sudo -E chroot '${ROOTFSDIR}' \
+      mkinitramfs -v -k -o /boot/initrd.img-${KERNEL_VERSION} ${KERNEL_VERSION}
+}
+
+addtask update_initramfs before do_copy_boot_files after do_rootfs_install
diff --git a/meta/recipes-support/initramfs-config/files/control.tmpl b/meta/recipes-support/initramfs-config/files/control.tmpl
new file mode 100644
index 0000000..5f57828
--- /dev/null
+++ b/meta/recipes-support/initramfs-config/files/control.tmpl
@@ -0,0 +1,12 @@
+Source: initramfs-config
+Section: misc
+Priority: optional
+Standards-Version: 3.9.6
+Maintainer: Unknown maintainer <unknown@example.com>
+Build-Depends: debhelper (>= 9)
+
+
+Package: initramfs-config
+Architecture: any
+Depends: ${shlibs:Depends}, ${misc:Depends}, initramfs-tools-core, ${KERNEL_PACKAGE}
+Description: Configuration files for a custom initramfs
\ No newline at end of file
diff --git a/meta/recipes-support/initramfs-config/files/postinst.tmpl b/meta/recipes-support/initramfs-config/files/postinst.tmpl
new file mode 100644
index 0000000..b03b09e
--- /dev/null
+++ b/meta/recipes-support/initramfs-config/files/postinst.tmpl
@@ -0,0 +1,28 @@
+#!/bin/bash
+set -x
+INITRAMFS_CONF=/etc/initramfs-tools/initramfs.conf
+if [ -f ${INITRAMFS_CONF} ]; then
+    sed -i -E 's/(^MODULES=).*/\1${INITRAMFS_MODULES}/' ${INITRAMFS_CONF}
+    sed -i -E 's/(^BUSYBOX=).*/\1${INITRAMFS_BUSYBOX}/' ${INITRAMFS_CONF}
+    sed -i -E 's/(^COMPRESS=).*/\1${INITRAMFS_COMPRESS}/' ${INITRAMFS_CONF}
+    sed -i -E 's/(^KEYMAP=).*/\1${INITRAMFS_KEYMAP}/' ${INITRAMFS_CONF}
+    sed -i -E 's/(^DEVICE=).*/\1${INITRAMFS_DEVICE}/' ${INITRAMFS_CONF}
+    sed -i -E 's/(^NFSROOT=).*/\1${INITRAMFS_NFSROOT}/' ${INITRAMFS_CONF}
+    sed -i -E 's/(^RUNSIZE=).*/\1${INITRAMFS_RUNSIZE}/' ${INITRAMFS_CONF}
+    if ! grep -Fxq "ROOT" "${INITRAMFS_CONF}"; then
+        sed -i -E 's/(^ROOT=).*/\1${INITRAMFS_ROOT}/' ${INITRAMFS_CONF}
+    else
+        sed -i -E "$aROOT=${INITRAMFS_ROOT}" ${INITRAMFS_CONF}
+    fi
+fi
+
+MODULES_LIST_FILE=/etc/initramfs-tools/modules
+if [ -f ${MODULES_LIST_FILE} ]; then
+    for modname in ${INITRAMFS_MODULE_LIST}; do
+        if ! grep -Fxq "$modname" "${MODULES_LIST_FILE}"; then
+            echo "$modname" >> "${MODULES_LIST_FILE}"
+        fi
+    done
+fi
+
+update-initramfs -v -u
diff --git a/meta/recipes-support/initramfs-config/initramfs-config_0.1.bb b/meta/recipes-support/initramfs-config/initramfs-config_0.1.bb
new file mode 100644
index 0000000..8352681
--- /dev/null
+++ b/meta/recipes-support/initramfs-config/initramfs-config_0.1.bb
@@ -0,0 +1,30 @@
+# This software is a part of ISAR.
+# Copyright (C) 2020 Siemens AG
+#
+# SPDX-License-Identifier: MIT
+inherit dpkg-raw
+inherit template
+DESCRIPTION = "Recipe to set the initramfs configuration and generate a new ramfs"
+
+
+SRC_URI = "file://postinst.tmpl \
+           file://control.tmpl \
+          "
+
+INITRAMFS_MODULES ?= "most"
+INITRAMFS_BUSYBOX ?= "auto"
+INITRAMFS_COMPRESS ?= "gzip"
+INITRAMFS_KEYMAP ?= "n"
+INITRAMFS_NET_DEVICE ?= ""
+INITRAMFS_NFSROOT ?= "auto"
+INITRAMFS_RUNSIZE ?= "10%"
+INITRAMFS_ROOT ?= ""
+INITRAMFS_MODULE_LIST ?= ""
+CREATE_NEW_INITRAMFS ?= "n"
+KERNEL_PACKAGE = "${@ ("linux-image-" + d.getVar("KERNEL_NAME", True)) if d.getVar("KERNEL_NAME", True) else ""}"
+TEMPLATE_FILES = "postinst.tmpl control.tmpl"
+TEMPLATE_VARS += "INITRAMFS_MODULES INITRAMFS_BUSYBOX INITRAMFS_COMPRESS \
+                  INITRAMFS_KEYMAP INITRAMFS_NET_DEVICE INITRAMFS_NFSROOT \
+                  INITRAMFS_RUNSIZE INITRAMFS_ROOT INITRAMFS_MODULE_LIST CREATE_NEW_INITRAMFS KERNEL_PACKAGE"
+
+
-- 
2.20.1