[RFC PATCH 2/2] recipes-core: Add recipe for base-files

[Vijai Kumar K <Vijaikumar_Kanagarajan@mentor.com>]

/etc/os-release is a symlink to /usr/lib/os-release and belongs to
the base-files package.

ISAR has been modifying the /etc/os-release during postprocessing
to inject custom data onto it.

Since this file belongs to base-files, an update/reinstall of the
package would overwrite the file with the one provided by base-files.

Instead of modifying the contents of /etc/os-release during
post-processing, provide a modified base-files recipe in ISAR which
provides the similar changes in os-release.

Signed-off-by: Vijai Kumar K <Vijaikumar_Kanagarajan@mentor.com>
---
 .../recipes-core/images/isar-image-base.bb    |  2 +
 meta/classes/image-postproc-extension.bbclass | 40 --------------
 meta/classes/image.bbclass                    | 20 -------
 meta/recipes-core/base-files/base-files.bb    |  6 ++
 meta/recipes-core/base-files/base-files.inc   | 55 +++++++++++++++++++
 5 files changed, 63 insertions(+), 60 deletions(-)
 create mode 100644 meta/recipes-core/base-files/base-files.bb
 create mode 100644 meta/recipes-core/base-files/base-files.inc

diff --git a/meta-isar/recipes-core/images/isar-image-base.bb b/meta-isar/recipes-core/images/isar-image-base.bb
index b381d85..4aa7e66 100644
--- a/meta-isar/recipes-core/images/isar-image-base.bb
+++ b/meta-isar/recipes-core/images/isar-image-base.bb
@@ -11,3 +11,5 @@ LIC_FILES_CHKSUM = "file://${LAYERDIR_core}/licenses/COPYING.GPLv2;md5=751419260
 PV = "1.0"
 
 inherit image
+
+IMAGE_INSTALL += "base-files"
diff --git a/meta/classes/image-postproc-extension.bbclass b/meta/classes/image-postproc-extension.bbclass
index 3f00c21..22c6a95 100644
--- a/meta/classes/image-postproc-extension.bbclass
+++ b/meta/classes/image-postproc-extension.bbclass
@@ -1,38 +1,6 @@
 # This software is a part of ISAR.
 # Copyright (C) Siemens AG, 2019
 
-update_etc_os_release() {
-    OS_RELEASE_BUILD_ID=""
-    OS_RELEASE_VARIANT=""
-    OS_RELEASE_VARIANT_VERSION=""
-    while true; do
-        case "$1" in
-        --build-id) OS_RELEASE_BUILD_ID=$2; shift ;;
-        --variant) OS_RELEASE_VARIANT=$2; shift ;;
-        --version) OS_RELEASE_VARIANT_VERSION=$2; shift ;;
-        -*) bbfatal "$0: invalid option specified: $1" ;;
-        *) break ;;
-        esac
-        shift
-    done
-
-    if [ -n "${OS_RELEASE_BUILD_ID}" ]; then
-        sudo sed -i '/^BUILD_ID=.*/d' '${IMAGE_ROOTFS}/etc/os-release'
-        echo "BUILD_ID=\"${OS_RELEASE_BUILD_ID}\"" | \
-            sudo tee -a '${IMAGE_ROOTFS}/etc/os-release'
-    fi
-    if [ -n "${OS_RELEASE_VARIANT}" ]; then
-        sudo sed -i '/^VARIANT=.*/d' '${IMAGE_ROOTFS}/etc/os-release'
-        echo "VARIANT=\"${OS_RELEASE_VARIANT}\"" | \
-            sudo tee -a '${IMAGE_ROOTFS}/etc/os-release'
-    fi
-    if [ -n "${OS_RELEASE_VARIANT_VERSION}" ]; then
-        sudo sed -i '/^ISAR_IMAGE_VERSION=.*/d' '${IMAGE_ROOTFS}/etc/os-release'
-        echo "VARIANT_VERSION=\"${PV}\"" | \
-            sudo tee -a '${IMAGE_ROOTFS}/etc/os-release'
-    fi
-}
-
 ROOTFS_POSTPROCESS_COMMAND =+ "image_postprocess_configure"
 image_postprocess_configure() {
     # Configure root filesystem
@@ -45,14 +13,6 @@ image_postprocess_configure() {
    fi
 }
 
-ROOTFS_POSTPROCESS_COMMAND =+ "image_postprocess_mark"
-
-image_postprocess_mark() {
-    BUILD_ID=$(get_build_id)
-    update_etc_os_release \
-        --build-id "${BUILD_ID}" --variant "${DESCRIPTION}" --version "${PV}"
-}
-
 ROOTFS_POSTPROCESS_COMMAND =+ "image_postprocess_machine_id"
 image_postprocess_machine_id() {
     # systemd(1) takes care of recreating the machine-id on first boot
diff --git a/meta/classes/image.bbclass b/meta/classes/image.bbclass
index eddc444..d849175 100644
--- a/meta/classes/image.bbclass
+++ b/meta/classes/image.bbclass
@@ -49,9 +49,6 @@ SRC_URI += "${@ cfg_script(d) }"
 
 DEPENDS += "${IMAGE_INSTALL}"
 
-ISAR_RELEASE_CMD_DEFAULT = "git -C ${LAYERDIR_core} describe --tags --dirty --match 'v[0-9].[0-9]*'"
-ISAR_RELEASE_CMD ?= "${ISAR_RELEASE_CMD_DEFAULT}"
-
 image_do_mounts() {
     sudo flock ${MOUNT_LOCKFILE} -c ' \
         mkdir -p "${BUILDROOT_DEPLOY}" "${BUILDROOT_ROOTFS}" "${BUILDROOT_WORK}"
@@ -91,23 +88,6 @@ def get_rootfs_size(d):
 
     return base_size + rootfs_extra * 1024
 
-# here we call a command that should describe your whole build system,
-# this could be "git describe" or something similar.
-# set ISAR_RELEASE_CMD to customize, or override do_mark_rootfs to do something
-# completely different
-get_build_id() {
-	if [ $(echo ${BBLAYERS} | wc -w) -ne 2 ] &&
-	   [ "${ISAR_RELEASE_CMD}" = "${ISAR_RELEASE_CMD_DEFAULT}" ]; then
-		bbwarn "You are using external layers that will not be" \
-		       "considered in the build_id. Consider changing" \
-		       "ISAR_RELEASE_CMD."
-	fi
-	if ! ( ${ISAR_RELEASE_CMD} ) 2>/dev/null; then
-		bbwarn "\"${ISAR_RELEASE_CMD}\" failed, returning empty build_id."
-		echo ""
-	fi
-}
-
 python set_image_size () {
     rootfs_size = get_rootfs_size(d)
     d.setVar('ROOTFS_SIZE', str(rootfs_size))
diff --git a/meta/recipes-core/base-files/base-files.bb b/meta/recipes-core/base-files/base-files.bb
new file mode 100644
index 0000000..d250fc5
--- /dev/null
+++ b/meta/recipes-core/base-files/base-files.bb
@@ -0,0 +1,6 @@
+# This software is a part of ISAR.
+# Copyright (c) Mentor, A Siemens Business, 2021
+#
+# SPDX-License-Identifier: MIT
+
+require base-files.inc
diff --git a/meta/recipes-core/base-files/base-files.inc b/meta/recipes-core/base-files/base-files.inc
new file mode 100644
index 0000000..68d0e3a
--- /dev/null
+++ b/meta/recipes-core/base-files/base-files.inc
@@ -0,0 +1,55 @@
+# This software is a part of ISAR.
+# Copyright (c) Mentor, A Siemens Business, 2021
+#
+# SPDX-License-Identifier: MIT
+
+inherit dpkg
+
+SRC_URI = "apt://${PN}"
+
+S="${WORKDIR}/${PN}"
+
+MAINTAINER = "isar-users <isar-users@googlegroups.com>"
+CHANGELOG_V = "<orig-version>+isar"
+
+ISAR_RELEASE_CMD_DEFAULT = "git -C ${LAYERDIR_core} describe --tags --dirty --match 'v[0-9].[0-9]*'"
+ISAR_RELEASE_CMD ?= "${ISAR_RELEASE_CMD_DEFAULT}"
+OS_RELEASE_VARIANT = "Isar target filesystem"
+OS_RELEASE_VARIANT_VERSION = "1.0"
+
+# here we call a command that should describe your whole build system,
+# this could be "git describe" or something similar.
+# set ISAR_RELEASE_CMD to customize, or override do_mark_rootfs to do something
+# completely different
+get_build_id() {
+    if [ $(echo ${BBLAYERS} | wc -w) -ne 2 ] &&
+       [ "${ISAR_RELEASE_CMD}" = "${ISAR_RELEASE_CMD_DEFAULT}" ]; then
+            bbwarn "You are using external layers that will not be" \
+                   "considered in the build_id. Consider changing" \
+                   "ISAR_RELEASE_CMD."
+    fi
+    if ! ( ${ISAR_RELEASE_CMD} ) 2>/dev/null; then
+        bbwarn "\"${ISAR_RELEASE_CMD}\" failed, returning empty build_id."
+        echo ""
+    fi
+}
+
+do_prepare_build() {
+    deb_add_changelog
+    OS_RELEASE_BUILD_ID=$(get_build_id)
+    if [ -n "${OS_RELEASE_BUILD_ID}" ]; then
+        sed -i '/^BUILD_ID=.*/d' '${S}/etc/os-release'
+        echo "BUILD_ID=\"${OS_RELEASE_BUILD_ID}\"" | \
+            tee -a '${S}/etc/os-release'
+    fi
+    if [ -n "${OS_RELEASE_VARIANT}" ]; then
+        sed -i '/^VARIANT=.*/d' '${S}/etc/os-release'
+        echo "VARIANT=\"${OS_RELEASE_VARIANT}\"" | \
+            tee -a '${S}/etc/os-release'
+    fi
+    if [ -n "${OS_RELEASE_VARIANT_VERSION}" ]; then
+        sed -i '/^VARIANT_VERSION=.*/d' '${S}/etc/os-release'
+        echo "VARIANT_VERSION=\"${OS_RELEASE_VARIANT_VERSION}\"" | \
+            tee -a '${S}/etc/os-release'
+    fi
+}
-- 
2.17.1