[RFC 12/15] dpkg-gbp: Migrate to schroot

[Anton Mikanovich <amikan@ilbers.de>]

Use schroot instead of chroot for git-buildpackage.

Signed-off-by: Anton Mikanovich <amikan@ilbers.de>
---
 meta/classes/dpkg-gbp.bbclass | 15 ++++-------
 meta/classes/sbuild.bbclass   | 48 +++++++++++++++++++++++++++++++++++
 2 files changed, 53 insertions(+), 10 deletions(-)

diff --git a/meta/classes/dpkg-gbp.bbclass b/meta/classes/dpkg-gbp.bbclass
index 0c60bda..e4e5ea6 100644
--- a/meta/classes/dpkg-gbp.bbclass
+++ b/meta/classes/dpkg-gbp.bbclass
@@ -13,18 +13,13 @@ GBP_DEPENDS ?= "git-buildpackage pristine-tar"
 GBP_EXTRA_OPTIONS ?= "--pristine-tar"
 
 do_prepare_build() {
-    deb_dl_dir_import "${BUILDCHROOT_DIR}" "${distro}"
-    sudo -E chroot ${BUILDCHROOT_DIR} \
-        apt-get install -y -o Debug::pkgProblemResolver=yes \
-                        --no-install-recommends --download-only ${GBP_DEPENDS}
-    deb_dl_dir_export "${BUILDCHROOT_DIR}" "${distro}"
-    sudo -E chroot ${BUILDCHROOT_DIR} \
-        apt-get install -y -o Debug::pkgProblemResolver=yes \
-                        --no-install-recommends ${GBP_DEPENDS}
+    schroot_install "${GBP_DEPENDS}"
 }
 do_prepare_build[lockfiles] += "${REPO_ISAR_DIR}/isar.lock"
 
+SCHROOT_MOUNTS = "${WORKDIR}:${PP}"
+
 dpkg_runbuild_prepend() {
-    sudo -E chroot --userspec=$( id -u ):$( id -g ) ${BUILDCHROOT_DIR} \
-        sh -c "cd ${PP}/${PPS} && gbp export-orig ${GBP_EXTRA_OPTIONS}"
+    schroot_run -d ${PP}/${PPS} -c ${SBUILD_CHROOT} -- \
+        gbp export-orig ${GBP_EXTRA_OPTIONS}
 }
diff --git a/meta/classes/sbuild.bbclass b/meta/classes/sbuild.bbclass
index cc7db66..3eede71 100644
--- a/meta/classes/sbuild.bbclass
+++ b/meta/classes/sbuild.bbclass
@@ -3,6 +3,8 @@
 
 SCHROOT_CONF ?= "/etc/schroot"
 
+SCHROOT_MOUNTS ?= ""
+
 python __anonymous() {
     mode = d.getVar('ISAR_CROSS_COMPILE', True)
     distro_arch = d.getVar('DISTRO_ARCH')
@@ -28,3 +30,49 @@ sbuild_export() {
     fi
     export SBUILD_CONFIG="${SBUILD_CONFIG}"
 }
+
+schroot_install() {
+    APTS="$1"
+    #TODO deb_dl_dir_import "${BUILDCHROOT_DIR}" "${distro}"
+    schroot -d / -c ${SBUILD_CHROOT_RW} -u root -- \
+        apt install -y -o Debug::pkgProblemResolver=yes \
+                    --no-install-recommends --download-only ${APTS}
+    #TODO deb_dl_dir_export "${BUILDCHROOT_DIR}" "${distro}"
+    schroot -d / -c ${SBUILD_CHROOT_RW} -u root -- \
+        apt install -y -o Debug::pkgProblemResolver=yes \
+                    --no-install-recommends ${APTS}
+}
+
+SCHROOT_FSTAB ?= "${SCHROOT_CONF}/${DEBDISTRONAME}-${@os.getlogin()}/fstab"
+SCHROOT_LOCKFILE ?= "schroot_fstab.lock"
+
+insert_mounts() {
+    sudo -s <<'EOSUDO'
+        ( flock 9
+        set -e
+        for mp in ${SCHROOT_MOUNTS}; do
+            FSTAB_LINE="${mp%%:*} ${mp#*:} none rw,bind 0 0"
+            grep -qxF "${FSTAB_LINE}" ${SCHROOT_FSTAB} || \
+                echo "${FSTAB_LINE}" >> ${SCHROOT_FSTAB}
+        done
+        ) 9>'${SCHROOT_LOCKFILE}'
+EOSUDO
+}
+
+remove_mounts() {
+    sudo -s <<'EOSUDO'
+        ( flock 9
+        set -e
+        for mp in ${SCHROOT_MOUNTS}; do
+            FSTAB_LINE="${mp%%:*} ${mp#*:} none rw,bind 0 0"
+            sed -i "\|${FSTAB_LINE}|d" ${SCHROOT_FSTAB}
+        done
+        ) 9>'${SCHROOT_LOCKFILE}'
+EOSUDO
+}
+
+schroot_run() {
+    insert_mounts
+    schroot $@
+    remove_mounts
+}
-- 
2.25.1