[RFC 03/15] isar-bootstrap: Export bootstrap to schroot config

[Anton Mikanovich <amikan@ilbers.de>]

To use isar-bootstrap with sbuild and schroot tools we need to export
the path to schroot config.

We also need to put isar-apt and downloads into fstab for sbuild
profile to have it mounted inside schroot.

Signed-off-by: Anton Mikanovich <amikan@ilbers.de>
---
 meta/classes/sbuild.bbclass                   | 17 ++++++
 .../isar-bootstrap/isar-bootstrap.inc         | 54 ++++++++++++++++++-
 2 files changed, 69 insertions(+), 2 deletions(-)
 create mode 100644 meta/classes/sbuild.bbclass

diff --git a/meta/classes/sbuild.bbclass b/meta/classes/sbuild.bbclass
new file mode 100644
index 0000000..ed2d0cf
--- /dev/null
+++ b/meta/classes/sbuild.bbclass
@@ -0,0 +1,17 @@
+# This software is a part of ISAR.
+# Copyright (C) 2021 ilbers GmbH
+
+SCHROOT_CONF ?= "/etc/schroot"
+
+python __anonymous() {
+    mode = d.getVar('ISAR_CROSS_COMPILE', True)
+    distro_arch = d.getVar('DISTRO_ARCH')
+    if mode == "0" or d.getVar('HOST_ARCH') ==  distro_arch or \
+       (d.getVar('HOST_DISTRO') == "debian-stretch" and distro_arch == "i386"):
+        d.setVar('SBUILD_HOST_ARCH', distro_arch)
+    else:
+        d.setVar('SBUILD_HOST_ARCH', d.getVar('HOST_ARCH'))
+}
+
+SBUILD_CHROOT ?= "${DEBDISTRONAME}-${@os.getlogin()}-${DISTRO}-${SBUILD_HOST_ARCH}"
+SBUILD_CHROOT_RW ?= "${DEBDISTRONAME}-${@os.getlogin()}-${DISTRO}-${SBUILD_HOST_ARCH}-rw"
diff --git a/meta/recipes-core/isar-bootstrap/isar-bootstrap.inc b/meta/recipes-core/isar-bootstrap/isar-bootstrap.inc
index 0edefc5..b4f352b 100644
--- a/meta/recipes-core/isar-bootstrap/isar-bootstrap.inc
+++ b/meta/recipes-core/isar-bootstrap/isar-bootstrap.inc
@@ -23,11 +23,12 @@ APTSRCS_INIT = "${WORKDIR}/apt-sources-init"
 DISTRO_BOOTSTRAP_KEYFILES = ""
 THIRD_PARTY_APT_KEYFILES = ""
 DEPLOY_ISAR_BOOTSTRAP ?= ""
-DISTRO_BOOTSTRAP_BASE_PACKAGES = "locales"
+DISTRO_BOOTSTRAP_BASE_PACKAGES = "locales,fakeroot,build-essential,debhelper"
 DISTRO_BOOTSTRAP_BASE_PACKAGES_append_gnupg = ",gnupg"
 DISTRO_BOOTSTRAP_BASE_PACKAGES_append_https-support = "${@https_support(d)}"
 
 inherit deb-dl-dir
+inherit sbuild
 
 python () {
     distro_bootstrap_keys = (d.getVar("DISTRO_BOOTSTRAP_KEYS") or "").split()
@@ -254,8 +255,9 @@ isar_bootstrap() {
     if [ "${ISAR_USE_CACHED_BASE_REPO}" = "1" -a -z "${BASE_REPO_KEY}" ]; then
         debootstrap_args="$debootstrap_args --no-check-gpg"
     fi
+    user_name=$(id -un)
     E="${@ isar_export_proxies(d)}"
-    export IS_HOST debootstrap_args E
+    export IS_HOST debootstrap_args E user_name
     if [ ! -e "${DEPLOY_ISAR_BOOTSTRAP}" ]; then
         sudo rm -rf --one-file-system "${ROOTFSDIR}"
         if [ "${IS_HOST}" ];then
@@ -266,6 +268,7 @@ isar_bootstrap() {
 
         sudo -E -s <<'EOSUDO'
             set -e
+            BOOTSTRAP_ARCH=${HOST_ARCH}
             if [ ${IS_HOST} ]; then
                 ${DEBOOTSTRAP} $debootstrap_args \
                                ${@get_distro_components_argument(d, True)} \
@@ -281,6 +284,53 @@ isar_bootstrap() {
                                "${ROOTFSDIR}" \
                                "${@get_distro_source(d, False)}" \
                                ${DISTRO_DEBOOTSTRAP_SCRIPT}
+                BOOTSTRAP_ARCH=${DISTRO_ARCH}
+            fi
+
+            cat << EOF > "${SCHROOT_CONF}/chroot.d/${DEBDISTRONAME}-${user_name}-${DISTRO}-${BOOTSTRAP_ARCH}"
+[${DEBDISTRONAME}-${user_name}-${DISTRO}-${BOOTSTRAP_ARCH}]
+type=directory
+directory=${ROOTFSDIR}
+profile=${DEBDISTRONAME}-${user_name}
+users=${user_name}
+groups=root,sbuild
+root-users=${user_name}
+root-groups=root,sbuild
+source-root-users=${user_name}
+source-root-groups=root,sbuild
+union-type=overlay
+preserve-environment=true
+
+[${DEBDISTRONAME}-${user_name}-${DISTRO}-${BOOTSTRAP_ARCH}-rw]
+type=directory
+directory=${ROOTFSDIR}
+profile=${DEBDISTRONAME}-${user_name}
+users=${user_name}
+groups=root,sbuild
+root-users=${user_name}
+root-groups=root,sbuild
+preserve-environment=true
+EOF
+
+            mkdir -p '${ROOTFSDIR}/etc/apt/preferences.d'
+            cat << EOF > '${ROOTFSDIR}/etc/apt/preferences.d/isar-apt'
+Package: *
+Pin: release n=${DEBDISTRONAME}
+Pin-Priority: 1000
+EOF
+
+            # Prepare mount points
+            if [ ! -d "${SCHROOT_CONF}/${DEBDISTRONAME}-${user_name}" ]; then
+                cp -r "${SCHROOT_CONF}/sbuild" "${SCHROOT_CONF}/${DEBDISTRONAME}-${user_name}"
+            fi
+            sbuild_fstab="${SCHROOT_CONF}/${DEBDISTRONAME}-${user_name}/fstab"
+
+            fstab_isarapt="${DEPLOY_DIR}/isar-apt /isar-apt none rw,bind 0 0"
+            grep -qxF "${fstab_isarapt}" ${sbuild_fstab} || echo "${fstab_isarapt}" >> ${sbuild_fstab}
+
+            if [ -d ${DL_DIR} ]; then
+                fstab_downloads="${DL_DIR} /downloads none rw,bind 0 0"
+                grep -qxF "${fstab_downloads}" ${sbuild_fstab} || echo "${fstab_downloads}" >> ${sbuild_fstab}
             fi
 
             # Install apt config
-- 
2.25.1