[PATCH v4 09/10] sstate: add caching to rootfs

[Adriaan Schmidt <adriaan.schmidt@siemens.com>]

We cache the output of do_rootfs. Again "sudo tar" to preserve
ownerships and permissions. In addition, it can happen that there are
active mounts while tar'ing the rootfs (there shouldn't be, but I've
seen cases where deb-src is mounted). Unfortunately --one-file-system
does not stop at bind mounts, so we use a trick with a temporary mount
to ensure that we don't package more than we want.

Special care needs to be taken with image and initramfs, which are
MACHINE specific. So they adapt sstate manifest location to ensure
that there is no false sharing.

Signed-off-by: Adriaan Schmidt <adriaan.schmidt@siemens.com>
---
 meta/classes/image.bbclass     |  3 +++
 meta/classes/initramfs.bbclass |  3 +++
 meta/classes/rootfs.bbclass    | 27 +++++++++++++++++++++++++++
 3 files changed, 33 insertions(+)

diff --git a/meta/classes/image.bbclass b/meta/classes/image.bbclass
index 5a0f32e..eedc160 100644
--- a/meta/classes/image.bbclass
+++ b/meta/classes/image.bbclass
@@ -6,6 +6,9 @@ WORKDIR = "${TMPDIR}/work/${DISTRO}-${DISTRO_ARCH}/${PN}-${MACHINE}-${IMAGE_TYPE
 STAMP = "${STAMPS_DIR}/${DISTRO}-${DISTRO_ARCH}/${PN}-${MACHINE}-${IMAGE_TYPE}/${PV}-${PR}"
 STAMPCLEAN = "${STAMPS_DIR}/${DISTRO}-${DISTRO_ARCH}/${PN}-${MACHINE}-${IMAGE_TYPE}/*-*"
 
+# Sstate also needs to be machine-specific
+SSTATE_MANIFESTS = "${TMPDIR}/sstate-control/${MACHINE}-${DISTRO}-${DISTRO_ARCH}"
+
 IMAGE_INSTALL ?= ""
 IMAGE_TYPE    ?= "ext4-img"
 IMAGE_ROOTFS ?= "${WORKDIR}/rootfs"
diff --git a/meta/classes/initramfs.bbclass b/meta/classes/initramfs.bbclass
index 10a642b..2cec85d 100644
--- a/meta/classes/initramfs.bbclass
+++ b/meta/classes/initramfs.bbclass
@@ -5,6 +5,9 @@ WORKDIR = "${TMPDIR}/work/${DISTRO}-${DISTRO_ARCH}/${PN}-${MACHINE}/${PV}-${PR}"
 STAMP = "${STAMPS_DIR}/${DISTRO}-${DISTRO_ARCH}/${PN}-${MACHINE}/${PV}-${PR}"
 STAMPCLEAN = "${STAMPS_DIR}/${DISTRO}-${DISTRO_ARCH}/${PN}-${MACHINE}/*-*"
 
+# Sstate also needs to be machine-specific
+SSTATE_MANIFESTS = "${TMPDIR}/sstate-control/${MACHINE}-${DISTRO}-${DISTRO_ARCH}"
+
 INITRAMFS_INSTALL ?= ""
 INITRAMFS_PREINSTALL ?= ""
 INITRAMFS_ROOTFS ?= "${WORKDIR}/rootfs"
diff --git a/meta/classes/rootfs.bbclass b/meta/classes/rootfs.bbclass
index b38de66..e0604e0 100644
--- a/meta/classes/rootfs.bbclass
+++ b/meta/classes/rootfs.bbclass
@@ -265,3 +265,30 @@ python do_rootfs() {
     pass
 }
 addtask rootfs before do_build
+
+do_rootfs[depends] = "base-apt:do_cache isar-apt:do_cache_config"
+
+SSTATETASKS += "do_rootfs"
+ROOTFS_SSTATE = "${WORKDIR}/rootfs-sstate"
+do_rootfs[dirs] += "${ROOTFS_SSTATE} ${WORKDIR}/mnt/rootfs"
+do_rootfs[cleandirs] += "${ROOTFS_SSTATE}"
+do_rootfs[sstate-plaindirs] = "${ROOTFS_SSTATE}"
+do_rootfs[sstate-interceptfuncs] = "rootfs_sstate_prepare"
+
+# the buildchroot is owned by root, so we need some sudoing to pack and unpack
+rootfs_sstate_prepare() {
+    sudo mount --bind ${WORKDIR}/rootfs ${WORKDIR}/mnt/rootfs -o ro
+    sudo tar -C ${WORKDIR}/mnt -cpf ${ROOTFS_SSTATE}/rootfs.tar --one-file-system rootfs
+    sudo umount ${WORKDIR}/mnt/rootfs
+}
+do_rootfs_sstate_prepare[lockfiles] = "${REPO_ISAR_DIR}/isar.lock"
+
+rootfs_sstate_finalize() {
+    sudo tar -C ${WORKDIR} -xpf ${ROOTFS_SSTATE}/rootfs.tar
+}
+
+python do_rootfs_setscene() {
+    sstate_setscene(d)
+    bb.build.exec_func('rootfs_sstate_finalize', d)
+}
+addtask do_rootfs_setscene
-- 
2.30.2