[PATCH v3 0/3] add support for debian build profiles

[PATCH v3 0/3] add support for debian build profiles

[Felix Moessbauer]

Changes since v2:

- only provide DEB_BUILD_PROFILES variable (no _CROSS variable)
- add "cross" directly to env variable when cross-compiling
- add DEB_BUILD_OPTIONS bitbake variable
  (profiles like "nocheck" must also add "nocheck" to DEB_BUILD_OPTIONS)
- update API changelog
- use DEB_BUILD_OPTIONS in hello.bb example

Changes since v1:

- fix erronous code removal reported by Vijai
- only use value of DEB_BUILD_PROFILES_CROSS when cross-compiling (no combination of values)
- improve API changelog docs
- rebased onto next
- use DEB_BUILD_PROFILES infrastructure in linux-custom.inc

Felix Moessbauer (3):
  add support for debian build profiles and options
  refactor linux-custom.inc to use ISAR's DEB_BUILD_PROFILES support
  Use DEB_BUILD_OPTIONS bb variable in hello.bb example

 RECIPE-API-CHANGELOG.md                          |  9 +++++++++
 meta-isar/recipes-app/hello/hello.bb             |  8 ++------
 meta/classes/dpkg-base.bbclass                   | 16 ++++++++++++++++
 meta/classes/dpkg.bbclass                        |  4 +++-
 .../recipes-bsp/libubootenv/libubootenv_0.3-3.bb |  5 +----
 meta/recipes-kernel/linux/linux-custom.inc       | 13 ++++++++-----
 6 files changed, 39 insertions(+), 16 deletions(-)

-- 
2.30.2

[PATCH v3 1/3] add support for debian build profiles and options

[Felix Moessbauer]

This patch adds the bitbake variables DEB_BUILD_PROFILES and DEB_BUILD_OPTIONS.
These are used to define the respective environment variables.

When cross-compiling, "cross" is added to the DEB_BUILD_PROFILES environment variable.

Signed-off-by: Felix Moessbauer <felix.moessbauer@siemens.com>
---
 RECIPE-API-CHANGELOG.md        |  9 +++++++++
 meta/classes/dpkg-base.bbclass | 16 ++++++++++++++++
 meta/classes/dpkg.bbclass      |  4 +++-
 3 files changed, 28 insertions(+), 1 deletion(-)

diff --git a/RECIPE-API-CHANGELOG.md b/RECIPE-API-CHANGELOG.md
index 3bbb42a9..65a1d9e4 100644
--- a/RECIPE-API-CHANGELOG.md
+++ b/RECIPE-API-CHANGELOG.md
@@ -314,3 +314,12 @@ The "NAME" used to be rather static and the TAG was always "latest", now the val
 ### Renamed variable CONTAINER_FORMATS to CONTAINER_IMAGE_FORMATS
 
 The meaning remains the same, just the name changed.
+### Introduce debian build profiles
+
+All recipes that inherit from dpkg and dpkg-base can utilize the variables DEB_BUILD_PROFILES and DEB_BUILD_OPTIONS.
+The bitbake variable defines the respective environment variable which is available in `do_install_builddeps` and `do_dpkg_build`.
+When cross compiling, `cross` is added to the DEB_BUILD_PROFILES environment variable.
+
+For a list of well-known Debian build profiles and common practices, we refer to Debian's BuildProfileSpec.
+
+
diff --git a/meta/classes/dpkg-base.bbclass b/meta/classes/dpkg-base.bbclass
index cb5ce4a9..ebf67ebc 100644
--- a/meta/classes/dpkg-base.bbclass
+++ b/meta/classes/dpkg-base.bbclass
@@ -13,6 +13,8 @@ inherit deb-dl-dir
 DEPENDS ?= ""
 
 DEPENDS_append_riscv64 = "${@' crossbuild-essential-riscv64' if d.getVar('ISAR_CROSS_COMPILE', True) == '1' and d.getVar('PN') != 'crossbuild-essential-riscv64' else ''}"
+DEB_BUILD_PROFILES ?= ""
+DEB_BUILD_OPTIONS ?= ""
 
 python do_adjust_git() {
     import subprocess
@@ -201,7 +203,20 @@ dpkg_runbuild() {
     die "This should never be called, overwrite it in your derived class"
 }
 
+def isar_export_build_settings(d):
+    import os
+    deb_build_profiles = os.environ['DEB_BUILD_PROFILES'] if 'DEB_BUILD_PROFILES' in os.environ else ''
+    deb_build_profiles += ' ' + d.getVar('DEB_BUILD_PROFILES', True)
+    if d.getVar("ISAR_CROSS_COMPILE") == "1":
+        deb_build_profiles += ' cross'
+    os.environ['DEB_BUILD_PROFILES'] = deb_build_profiles.strip()
+
+    deb_build_options = os.environ['DEB_BUILD_OPTIONS'] if 'DEB_BUILD_OPTIONS' in os.environ else ''
+    deb_build_options += ' ' + d.getVar('DEB_BUILD_OPTIONS', True)
+    os.environ['DEB_BUILD_OPTIONS'] = deb_build_options.strip()
+
 python do_dpkg_build() {
+    isar_export_build_settings(d)
     lock = bb.utils.lockfile(d.getVar("REPO_ISAR_DIR") + "/isar.lock",
                              shared=True)
     bb.build.exec_func("dpkg_do_mounts", d)
@@ -279,6 +294,7 @@ python do_devshell() {
 
     isar_export_proxies(d)
     isar_export_ccache(d)
+    isar_export_build_settings(d)
 
     buildchroot = d.getVar('BUILDCHROOT_DIR')
     pp_pps = os.path.join(d.getVar('PP'), d.getVar('PPS'))
diff --git a/meta/classes/dpkg.bbclass b/meta/classes/dpkg.bbclass
index 27fe84f4..67d63813 100644
--- a/meta/classes/dpkg.bbclass
+++ b/meta/classes/dpkg.bbclass
@@ -9,10 +9,12 @@ PACKAGE_ARCH ?= "${DISTRO_ARCH}"
 do_install_builddeps() {
     dpkg_do_mounts
     E="${@ isar_export_proxies(d)}"
+    E="${@ isar_export_build_settings(d)}"
     distro="${DISTRO}"
     if [ ${ISAR_CROSS_COMPILE} -eq 1 ]; then
-       distro="${HOST_DISTRO}"
+        distro="${HOST_DISTRO}"
     fi
+
     deb_dl_dir_import "${BUILDCHROOT_DIR}" "${distro}"
     sudo -E chroot ${BUILDCHROOT_DIR} /isar/deps.sh \
         ${PP}/${PPS} ${PACKAGE_ARCH} --download-only
-- 
2.30.2

Re: [PATCH v3 1/3] add support for debian build profiles and options

[vijai kumar]

On Tue, Jan 4, 2022 at 6:31 PM Felix Moessbauer
<felix.moessbauer@siemens.com> wrote:
>
> This patch adds the bitbake variables DEB_BUILD_PROFILES and DEB_BUILD_OPTIONS.
> These are used to define the respective environment variables.
>
> When cross-compiling, "cross" is added to the DEB_BUILD_PROFILES environment variable.
>
> Signed-off-by: Felix Moessbauer <felix.moessbauer@siemens.com>
> ---
>  RECIPE-API-CHANGELOG.md        |  9 +++++++++
>  meta/classes/dpkg-base.bbclass | 16 ++++++++++++++++
>  meta/classes/dpkg.bbclass      |  4 +++-
>  3 files changed, 28 insertions(+), 1 deletion(-)
>
> diff --git a/RECIPE-API-CHANGELOG.md b/RECIPE-API-CHANGELOG.md
> index 3bbb42a9..65a1d9e4 100644
> --- a/RECIPE-API-CHANGELOG.md
> +++ b/RECIPE-API-CHANGELOG.md
> @@ -314,3 +314,12 @@ The "NAME" used to be rather static and the TAG was always "latest", now the val
>  ### Renamed variable CONTAINER_FORMATS to CONTAINER_IMAGE_FORMATS
>
>  The meaning remains the same, just the name changed.
> +### Introduce debian build profiles
> +
> +All recipes that inherit from dpkg and dpkg-base can utilize the variables DEB_BUILD_PROFILES and DEB_BUILD_OPTIONS.
> +The bitbake variable defines the respective environment variable which is available in `do_install_builddeps` and `do_dpkg_build`.
> +When cross compiling, `cross` is added to the DEB_BUILD_PROFILES environment variable.
> +
> +For a list of well-known Debian build profiles and common practices, we refer to Debian's BuildProfileSpec.
> +
> +
> diff --git a/meta/classes/dpkg-base.bbclass b/meta/classes/dpkg-base.bbclass
> index cb5ce4a9..ebf67ebc 100644
> --- a/meta/classes/dpkg-base.bbclass
> +++ b/meta/classes/dpkg-base.bbclass
> @@ -13,6 +13,8 @@ inherit deb-dl-dir
>  DEPENDS ?= ""
>
>  DEPENDS_append_riscv64 = "${@' crossbuild-essential-riscv64' if d.getVar('ISAR_CROSS_COMPILE', True) == '1' and d.getVar('PN') != 'crossbuild-essential-riscv64' else ''}"
> +DEB_BUILD_PROFILES ?= ""
> +DEB_BUILD_OPTIONS ?= ""
>
>  python do_adjust_git() {
>      import subprocess
> @@ -201,7 +203,20 @@ dpkg_runbuild() {
>      die "This should never be called, overwrite it in your derived class"
>  }
>
> +def isar_export_build_settings(d):
> +    import os
> +    deb_build_profiles = os.environ['DEB_BUILD_PROFILES'] if 'DEB_BUILD_PROFILES' in os.environ else ''

Like said in the previous thread. If this is eventually going to be
dropped, a warning to the user would be needed so that he could notice
and migrate to the DEB_BUILD_PROFILES/OPTIONS variable instead of a
manual export.

Thanks,
Vijai Kumar K

> +    deb_build_profiles += ' ' + d.getVar('DEB_BUILD_PROFILES', True)
> +    if d.getVar("ISAR_CROSS_COMPILE") == "1":
> +        deb_build_profiles += ' cross'
> +    os.environ['DEB_BUILD_PROFILES'] = deb_build_profiles.strip()
> +
> +    deb_build_options = os.environ['DEB_BUILD_OPTIONS'] if 'DEB_BUILD_OPTIONS' in os.environ else ''
> +    deb_build_options += ' ' + d.getVar('DEB_BUILD_OPTIONS', True)
> +    os.environ['DEB_BUILD_OPTIONS'] = deb_build_options.strip()
> +
>  python do_dpkg_build() {
> +    isar_export_build_settings(d)
>      lock = bb.utils.lockfile(d.getVar("REPO_ISAR_DIR") + "/isar.lock",
>                               shared=True)
>      bb.build.exec_func("dpkg_do_mounts", d)
> @@ -279,6 +294,7 @@ python do_devshell() {
>
>      isar_export_proxies(d)
>      isar_export_ccache(d)
> +    isar_export_build_settings(d)
>
>      buildchroot = d.getVar('BUILDCHROOT_DIR')
>      pp_pps = os.path.join(d.getVar('PP'), d.getVar('PPS'))
> diff --git a/meta/classes/dpkg.bbclass b/meta/classes/dpkg.bbclass
> index 27fe84f4..67d63813 100644
> --- a/meta/classes/dpkg.bbclass
> +++ b/meta/classes/dpkg.bbclass
> @@ -9,10 +9,12 @@ PACKAGE_ARCH ?= "${DISTRO_ARCH}"
>  do_install_builddeps() {
>      dpkg_do_mounts
>      E="${@ isar_export_proxies(d)}"
> +    E="${@ isar_export_build_settings(d)}"
>      distro="${DISTRO}"
>      if [ ${ISAR_CROSS_COMPILE} -eq 1 ]; then
> -       distro="${HOST_DISTRO}"
> +        distro="${HOST_DISTRO}"
>      fi
> +
>      deb_dl_dir_import "${BUILDCHROOT_DIR}" "${distro}"
>      sudo -E chroot ${BUILDCHROOT_DIR} /isar/deps.sh \
>          ${PP}/${PPS} ${PACKAGE_ARCH} --download-only
> --
> 2.30.2
>

[PATCH v3 2/3] refactor linux-custom.inc to use ISAR's DEB_BUILD_PROFILES support

[Felix Moessbauer]

This patch replaces the manual setup of the DEB_BUILD_PROFILES
environment variable in the linux-custom.inc recipe.
Instead, the recently introduced DEB_BUILD_PROFILES infrastructure
of ISAR is used.

Signed-off-by: Felix Moessbauer <felix.moessbauer@siemens.com>
---
 meta/recipes-kernel/linux/linux-custom.inc | 13 ++++++++-----
 1 file changed, 8 insertions(+), 5 deletions(-)

diff --git a/meta/recipes-kernel/linux/linux-custom.inc b/meta/recipes-kernel/linux/linux-custom.inc
index ed89aa09..59d42c84 100644
--- a/meta/recipes-kernel/linux/linux-custom.inc
+++ b/meta/recipes-kernel/linux/linux-custom.inc
@@ -117,6 +117,14 @@ def config_fragments(d):
             fragments.append(local)
     return fragments
 
+def get_additional_build_profiles(d):
+    profiles = d.getVar('BASE_DISTRO', True)
+    if d.getVar('KERNEL_LIBC_DEV_DEPLOY', True) != '1':
+        profiles += ' nolibcdev'
+    return profiles
+
+DEB_BUILD_PROFILES += "${@get_additional_build_profiles(d)}"
+
 do_prepare_build_prepend() {
 	# copy meta-data over to source tree
 	rm -rf ${S}/debian
@@ -176,10 +184,5 @@ dpkg_configure_kernel() {
 }
 
 dpkg_runbuild_prepend() {
-	profiles="${BASE_DISTRO}"
-	if [ "${KERNEL_LIBC_DEV_DEPLOY}" != "1" ]; then
-		profiles="${profiles} nolibcdev"
-	fi
-	export DEB_BUILD_PROFILES="${profiles}"
 	dpkg_configure_kernel
 }
-- 
2.30.2

[PATCH v3 3/3] Use DEB_BUILD_OPTIONS bb variable in hello.bb example

[Felix Moessbauer]

Signed-off-by: Felix Moessbauer <felix.moessbauer@siemens.com>
---
 meta-isar/recipes-app/hello/hello.bb              | 8 ++------
 meta/recipes-bsp/libubootenv/libubootenv_0.3-3.bb | 5 +----
 2 files changed, 3 insertions(+), 10 deletions(-)

diff --git a/meta-isar/recipes-app/hello/hello.bb b/meta-isar/recipes-app/hello/hello.bb
index d6bdf9bb..acf8ed73 100644
--- a/meta-isar/recipes-app/hello/hello.bb
+++ b/meta-isar/recipes-app/hello/hello.bb
@@ -15,6 +15,8 @@ SRC_URI = "apt://${PN}"
 MAINTAINER = "isar-users <isar-users@googlegroups.com>"
 CHANGELOG_V = "<orig-version>+isar"
 
+DEB_BUILD_OPTIONS += "${@ 'nocheck' if d.getVar('ISAR_CROSS_COMPILE') == '1' else '' }"
+
 do_prepare_build() {
 	deb_add_changelog
 	# this seems to be a build dep missing in the upstream control file
@@ -22,9 +24,3 @@ do_prepare_build() {
 		sed -i -e 's/Build-Depends:/Build-Depends: texinfo,/g' ${S}/debian/control
 	fi
 }
-
-dpkg_runbuild_prepend() {
-	if [ ${ISAR_CROSS_COMPILE} -eq 1 ]; then
-		export DEB_BUILD_OPTIONS="nocheck"
-	fi
-}
diff --git a/meta/recipes-bsp/libubootenv/libubootenv_0.3-3.bb b/meta/recipes-bsp/libubootenv/libubootenv_0.3-3.bb
index 68a55003..9af01aa7 100644
--- a/meta/recipes-bsp/libubootenv/libubootenv_0.3-3.bb
+++ b/meta/recipes-bsp/libubootenv/libubootenv_0.3-3.bb
@@ -19,7 +19,4 @@ SRCREV = "a1a3504e5cda1883928a8747a0bedc56afff6910"
 
 S = "${WORKDIR}/git"
 
-
-dpkg_runbuild_prepend() {
-	export DEB_BUILD_OPTIONS="nocheck"
-}
+DEB_BUILD_OPTIONS += "nocheck"
-- 
2.30.2