public inbox for isar-users@googlegroups.com
 help / color / mirror / Atom feed
From: Felix Moessbauer <felix.moessbauer@siemens.com>
To: isar-users@googlegroups.com
Cc: henning.schild@siemens.com,
	Felix Moessbauer <felix.moessbauer@siemens.com>
Subject: [PATCH v2 1/1] add support for derived sbuild chroots
Date: Sun, 25 Jun 2023 05:54:42 +0000	[thread overview]
Message-ID: <20230625055442.1569823-1-felix.moessbauer@siemens.com> (raw)

This patch adds support to create derived sbuild chroots to speedup the
build process. For packages that share a large set of common build
dependencies, a derived sbuild chroot can be created to avoid the
overhead of installing all base build-deps on each sbuild invocation.

Signed-off-by: Felix Moessbauer <felix.moessbauer@siemens.com>
---
Changes since v1:

- dropped example
- add variable SBUILD_CHROOT_PREINSTALL_EXTRA to add packages

 doc/user_manual.md                            | 26 +++++++++++++++++++
 meta/classes/crossvars.bbclass                | 11 +++++---
 .../sbuild-chroot/sbuild-chroot.inc           |  9 ++++++-
 3 files changed, 42 insertions(+), 4 deletions(-)

diff --git a/doc/user_manual.md b/doc/user_manual.md
index e07b76d8..106d2dca 100644
--- a/doc/user_manual.md
+++ b/doc/user_manual.md
@@ -1406,3 +1406,29 @@ To enable it, add the below line to your local.conf file.
 ```
 BASE_REPO_FEATURES = "cache-deb-src"
 ```
+
+## Use a custom sbuild chroot to speedup build
+
+### Motivation
+
+There are use-cases, where many packages need to be compiled but all of them
+need a similar base of build dependencies. In case the baseline is quite big,
+this adds a significant overhead as the build dependencies are installed individually
+for each and every package.
+
+### Solution
+
+By creating a dedicated sbuild chroot for this use-case, the baseline can be installed
+first and then all package builds of this type can use it. For that, create a
+new recipe with the name `sbuild-chroot-<host|target>-<flavor>`. In that recipe,
+define the following:
+
+```
+require recipes-devtools/sbuild-chroot/sbuild-chroot-<host|target>.bb
+
+SBUILD_FLAVOR = "<your flavor, e.g. clang>"
+SBUILD_CHROOT_PREINSTALL_EXTRA += "<base packages>"
+```
+
+Then, in the dpkg recipe of your package, simply set `SBUILD_FLAVOR = "<your flavor>"`.
+To install additional packages into the sbuild chroot, add them to `SBUILD_CHROOT_PREINSTALL_EXTRA`.
diff --git a/meta/classes/crossvars.bbclass b/meta/classes/crossvars.bbclass
index 201d460f..8d1da09c 100644
--- a/meta/classes/crossvars.bbclass
+++ b/meta/classes/crossvars.bbclass
@@ -10,22 +10,27 @@ python __anonymous() {
     d.setVar('SCHROOT_USER', pwd.getpwuid(os.geteuid()).pw_name)
 
     mode = d.getVar('ISAR_CROSS_COMPILE')
+
+    # support derived schroots
+    flavor = d.getVar('SBUILD_FLAVOR')
+    flavor_suffix = ('-' + flavor) if flavor else ''
+
     distro_arch = d.getVar('DISTRO_ARCH')
     if mode == "0" or d.getVar('HOST_ARCH') == distro_arch or distro_arch == None:
         d.setVar('BUILD_HOST_ARCH', distro_arch)
         schroot_dir = d.getVar('SCHROOT_TARGET_DIR', False)
-        sbuild_dep = "sbuild-chroot-target:do_build"
+        sbuild_dep = "sbuild-chroot-target" + flavor_suffix + ":do_build"
         buildchroot_dir = d.getVar('BUILDCHROOT_TARGET_DIR', False)
         buildchroot_dep = "buildchroot-target:do_build"
         sdk_toolchain = "build-essential"
     else:
         d.setVar('BUILD_HOST_ARCH', d.getVar('HOST_ARCH'))
         schroot_dir = d.getVar('SCHROOT_HOST_DIR', False)
-        sbuild_dep = "sbuild-chroot-host:do_build"
+        sbuild_dep = "sbuild-chroot-host" + flavor_suffix + ":do_build"
         buildchroot_dir = d.getVar('BUILDCHROOT_HOST_DIR', False)
         buildchroot_dep = "buildchroot-host:do_build"
         sdk_toolchain = "crossbuild-essential-" + distro_arch
-    d.setVar('SCHROOT_DIR', schroot_dir)
+    d.setVar('SCHROOT_DIR', schroot_dir + flavor_suffix)
     d.setVar('SCHROOT_DEP', sbuild_dep)
     d.setVar('BUILDCHROOT_DIR', buildchroot_dir)
     d.setVar('BUILDCHROOT_DEP', buildchroot_dep)
diff --git a/meta/recipes-devtools/sbuild-chroot/sbuild-chroot.inc b/meta/recipes-devtools/sbuild-chroot/sbuild-chroot.inc
index fd8bb648..c572456e 100644
--- a/meta/recipes-devtools/sbuild-chroot/sbuild-chroot.inc
+++ b/meta/recipes-devtools/sbuild-chroot/sbuild-chroot.inc
@@ -11,6 +11,12 @@ PV = "1.0"
 inherit rootfs
 inherit compat
 
+# set the flavor to create derived sbuild chroots
+# this maps to a schroot created by a recipe named sbuild-chroot-<host|target>-<flavor>
+SBUILD_FLAVOR ??= ""
+SBUILD_SCHROOT_SUFFIX = "${@ ('-' + d.getVar('SBUILD_FLAVOR')) if d.getVar('SBUILD_FLAVOR') else ''}"
+SBUILD_CHROOT_PREINSTALL_EXTRA ??= ""
+
 python() {
     distro_gcc = d.getVar('DISTRO_GCC')
     distro_arch = d.getVar('DISTRO_ARCH')
@@ -36,6 +42,7 @@ python() {
 
 SBUILD_CHROOT_PREINSTALL_COMMON = " \
     ${SBUILD_CHROOT_COMPAT_PREINSTALL} \
+    ${SBUILD_CHROOT_PREINSTALL_EXTRA} \
     libc6-dev:${DISTRO_ARCH} \
     fakeroot \
     build-essential \
@@ -52,7 +59,7 @@ ROOTFS_PACKAGES = "${SBUILD_CHROOT_PREINSTALL}"
 # We don't need /etc/apt/sources.list.d/isar-apt.list' while it's handled by sbuild
 ROOTFS_CONFIGURE_COMMAND:remove = "rootfs_configure_isar_apt"
 
-DEPLOY_SCHROOT = "${@d.getVar('SCHROOT_' + d.getVar('SBUILD_VARIANT').upper() + '_DIR')}"
+DEPLOY_SCHROOT = "${@d.getVar('SCHROOT_' + d.getVar('SBUILD_VARIANT').upper() + '_DIR')}${SBUILD_SCHROOT_SUFFIX}"
 
 do_sbuildchroot_deploy[dirs] = "${DEPLOY_DIR}/schroot-${SBUILD_VARIANT}"
 do_sbuildchroot_deploy() {
-- 
2.34.1


             reply	other threads:[~2023-06-25  5:55 UTC|newest]

Thread overview: 2+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
2023-06-25  5:54 Felix Moessbauer [this message]
2023-06-30 11:55 ` Uladzimir Bely

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=20230625055442.1569823-1-felix.moessbauer@siemens.com \
    --to=felix.moessbauer@siemens.com \
    --cc=henning.schild@siemens.com \
    --cc=isar-users@googlegroups.com \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox