[PATCH] features_check: add bbclass from oe-core 1a2afcd0

[PATCH] features_check: add bbclass from oe-core 1a2afcd0

[chris.larson via isar-users]

From: Christopher Larson <chris.larson@siemens.com>

Allow checking of required and conflicting features.

    xxx = [DISTRO,MACHINE,COMBINED,IMAGE,BSP,ROOTFS]

    ANY_OF_xxx_FEATURES:        ensure at least one item on this list is included
                                in xxx_FEATURES.
    REQUIRED_xxx_FEATURES:      ensure every item on this list is included
                                in xxx_FEATURES.
    CONFLICT_xxx_FEATURES:      ensure no item in this list is included in
                                xxx_FEATURES.

This allows one to easily specify that a given feature is required for a
recipe. By using this with the new features variables, we can ensure
that features are set correctly for a given recipe.

We can use simple checks like this:

    REQUIRED_BSP_FEATURES += "some-bsp-feature"

In combination with inline python, we can implement behaviors and checks
like this:

    # Enable the 'wayland' image feature if the machine feature is enabled.
    IMAGE_FEATURES:append = " ${@bb.utils.filter('MACHINE_FEATURES', 'wayland', d)}"

    # Require the 'wayland' machine feature when the image feature is enabled.
    REQUIRED_MACHINE_FEATURES += "${@bb.utils.filter('IMAGE_FEATURES', 'wayland', d)}"

Signed-off-by: Christopher Larson <chris.larson@siemens.com>
---
 meta/classes/features_check.bbclass | 57 +++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 meta/classes/features_check.bbclass

diff --git a/meta/classes/features_check.bbclass b/meta/classes/features_check.bbclass
new file mode 100644
index 00000000..304501b0
--- /dev/null
+++ b/meta/classes/features_check.bbclass
@@ -0,0 +1,57 @@
+# Allow checking of required and conflicting features
+#
+# xxx = [DISTRO,MACHINE,COMBINED,IMAGE,BSP,ROOTFS]
+#
+# ANY_OF_xxx_FEATURES:        ensure at least one item on this list is included
+#                             in xxx_FEATURES.
+# REQUIRED_xxx_FEATURES:      ensure every item on this list is included
+#                             in xxx_FEATURES.
+# CONFLICT_xxx_FEATURES:      ensure no item in this list is included in
+#                             xxx_FEATURES.
+#
+# Copyright 2019 (C) Texas Instruments Inc.
+# Copyright 2013 (C) O.S. Systems Software LTDA.
+#
+# SPDX-License-Identifier: MIT
+
+
+python () {
+    if bb.utils.to_boolean(d.getVar('PARSE_ALL_RECIPES', False)):
+        return
+
+    unused = True
+
+    for kind in ['DISTRO', 'MACHINE', 'COMBINED', 'IMAGE', 'BSP', 'ROOTFS']:
+        if d.getVar('ANY_OF_' + kind + '_FEATURES') is None and not d.hasOverrides('ANY_OF_' + kind + '_FEATURES') and \
+           d.getVar('REQUIRED_' + kind + '_FEATURES') is None and not d.hasOverrides('REQUIRED_' + kind + '_FEATURES') and \
+           d.getVar('CONFLICT_' + kind + '_FEATURES') is None and not d.hasOverrides('CONFLICT_' + kind + '_FEATURES'):
+            continue
+
+        unused = False
+
+        # Assume at least one var is set.
+        features = set((d.getVar(kind + '_FEATURES') or '').split())
+
+        any_of_features = set((d.getVar('ANY_OF_' + kind + '_FEATURES') or '').split())
+        if any_of_features:
+            if set.isdisjoint(any_of_features, features):
+                raise bb.parse.SkipRecipe("one of '%s' needs to be in %s_FEATURES"
+                    % (' '.join(any_of_features), kind))
+
+        required_features = set((d.getVar('REQUIRED_' + kind + '_FEATURES') or '').split())
+        if required_features:
+            missing = set.difference(required_features, features)
+            if missing:
+                raise bb.parse.SkipRecipe("missing required %s feature%s '%s' (not in %s_FEATURES)"
+                    % (kind.lower(), 's' if len(missing) > 1 else '', ' '.join(missing), kind))
+
+        conflict_features = set((d.getVar('CONFLICT_' + kind + '_FEATURES') or '').split())
+        if conflict_features:
+            conflicts = set.intersection(conflict_features, features)
+            if conflicts:
+                raise bb.parse.SkipRecipe("conflicting %s feature%s '%s' (in %s_FEATURES)"
+                    % (kind.lower(), 's' if len(conflicts) > 1 else '', ' '.join(conflicts), kind))
+
+    if unused:
+        bb.warn("Recipe inherits features_check but doesn't use it")
+}
-- 
2.47.2

-- 
You received this message because you are subscribed to the Google Groups "isar-users" group.
To unsubscribe from this group and stop receiving emails from it, send an email to isar-users+unsubscribe@googlegroups.com.
To view this discussion visit https://groups.google.com/d/msgid/isar-users/20250328202532.15607-1-chris.larson%40siemens.com.

Re: [PATCH] features_check: add bbclass from oe-core 1a2afcd0

[Anton Mikanovich]

28/03/2025 22:25, chris.larson via isar-users wrote:
> From: Christopher Larson <chris.larson@siemens.com>
>
> Allow checking of required and conflicting features.
>
>      xxx = [DISTRO,MACHINE,COMBINED,IMAGE,BSP,ROOTFS]
>
>      ANY_OF_xxx_FEATURES:        ensure at least one item on this list is included
>                                  in xxx_FEATURES.
>      REQUIRED_xxx_FEATURES:      ensure every item on this list is included
>                                  in xxx_FEATURES.
>      CONFLICT_xxx_FEATURES:      ensure no item in this list is included in
>                                  xxx_FEATURES.
>
> This allows one to easily specify that a given feature is required for a
> recipe. By using this with the new features variables, we can ensure
> that features are set correctly for a given recipe.
>
> We can use simple checks like this:
>
>      REQUIRED_BSP_FEATURES += "some-bsp-feature"
>
> In combination with inline python, we can implement behaviors and checks
> like this:
>
>      # Enable the 'wayland' image feature if the machine feature is enabled.
>      IMAGE_FEATURES:append = " ${@bb.utils.filter('MACHINE_FEATURES', 'wayland', d)}"
>
>      # Require the 'wayland' machine feature when the image feature is enabled.
>      REQUIRED_MACHINE_FEATURES += "${@bb.utils.filter('IMAGE_FEATURES', 'wayland', d)}"
>
> Signed-off-by: Christopher Larson <chris.larson@siemens.com>

Applied to next, thanks.

-- 
You received this message because you are subscribed to the Google Groups "isar-users" group.
To unsubscribe from this group and stop receiving emails from it, send an email to isar-users+unsubscribe@googlegroups.com.
To view this discussion visit https://groups.google.com/d/msgid/isar-users/a7f93186-5798-4ca7-915f-2013b908391a%40ilbers.de.