[v8 02/14] meta: Add debrepo bbclass handling base-apt prefetching

[Aliaksei Karpovich <akarpovich@ilbers.de>]

From: Uladzimir Bely <ubely@ilbers.de>

This class uses 'scripts/debrepo' python script to prefetch given
packages or sources to local base-apt repository.

Signed-off-by: Uladzimir Bely <ubely@ilbers.de>
---
 RECIPE-API-CHANGELOG.md      | 10 ++++
 doc/user_manual.md           |  1 +
 meta/classes/debrepo.bbclass | 90 ++++++++++++++++++++++++++++++++++++
 meta/conf/bitbake.conf       |  5 ++
 4 files changed, 106 insertions(+)
 create mode 100644 meta/classes/debrepo.bbclass

diff --git a/RECIPE-API-CHANGELOG.md b/RECIPE-API-CHANGELOG.md
index f5b84c84..7f89d121 100644
--- a/RECIPE-API-CHANGELOG.md
+++ b/RECIPE-API-CHANGELOG.md
@@ -1137,3 +1137,13 @@ targeting Microsoft Hyper-V virtual machines on amd64.
 The machine produces a `.vhdx` disk image using the WIC image type
 and GRUB as the bootloader. It supports Debian bullseye, bookworm
 and trixie.
+
+### "Prefetch" mode for base-apt
+
+Originally, `base-apt` repo is created only during second build when variable
+ISAR_USE_CACHED_BASE_REPO is set. The repo is populated with every package that
+took part in the first build and was cached in DL_DIR.
+
+New ISAR_PREFETCH_BASE_APT variable changes the way `base-apt` is populated.
+Packages added to the repo before running any task that need them. Separate
+`debrepo` script is used for populating base-apt repo.
diff --git a/doc/user_manual.md b/doc/user_manual.md
index dcc3f560..aa2b68b9 100644
--- a/doc/user_manual.md
+++ b/doc/user_manual.md
@@ -86,6 +86,7 @@ apt install \
   gettext-base \
   git \
   python3 \
+  python3-apt \
   quilt \
   qemu-user-static \
   reprepro \
diff --git a/meta/classes/debrepo.bbclass b/meta/classes/debrepo.bbclass
new file mode 100644
index 00000000..b4db9219
--- /dev/null
+++ b/meta/classes/debrepo.bbclass
@@ -0,0 +1,90 @@
+# This software is a part of Isar.
+# Copyright (C) 2026 ilbers GmbH
+#
+# SPDX-License-Identifier: MIT
+
+# Prefetch to base-apt repo by default
+ISAR_PREFETCH_BASE_APT ??= "1"
+
+DEBREPO_WORKDIR ??= "${DEBREPO_TARGET_DIR}"
+
+debrepo_update_apt_source_list() {
+    [ "${ISAR_PREFETCH_BASE_APT}" != "1" ] && return
+
+    chroot_dir=${1}
+    apt_list=${2}
+
+    flock -x "${REPO_BASE_DIR}/repo.lock" -c "
+        sudo -E chroot ${chroot_dir} /usr/bin/apt-get update \
+            -o Dir::Etc::SourceList=\"sources.list.d/${apt_list}.list\" \
+            -o Dir::Etc::SourceParts=\"-\" \
+            -o APT::Get::List-Cleanup=\"0\"
+    "
+}
+
+debrepo_add_packages() {
+    [ "${ISAR_PREFETCH_BASE_APT}" != "1" ] && return
+    [ "${ISAR_USE_CACHED_BASE_REPO}" = "1" ] && return
+
+    args=""
+    if [ "${1}" = "--srcmode" ]; then
+        args="${args} --srcmode"
+        shift
+    fi
+
+    if [ "${1}" = "--isarapt" ]; then
+        args="${args} --extrarepo=${REPO_ISAR_DIR}/${DISTRO}"
+        shift
+    fi
+
+    workdir="${1}"
+    args="${args} ${2}"
+
+    if [ -n "${GNUPGHOME}" ]; then
+        export GNUPGHOME="${GNUPGHOME}"
+    else
+        export GNUPGHOME="${WORKDIR}/gpghome"
+    fi
+
+    ${SCRIPTSDIR}/debrepo \
+        --workdir="${workdir}" \
+        ${args}
+}
+
+debrepo_parse_dscfile() {
+    [ "${ISAR_PREFETCH_BASE_APT}" != "1" ] && return
+    [ "${ISAR_USE_CACHED_BASE_REPO}" = "1" ] && return
+
+    dscfile="${1}"
+    args=""
+
+    build_arch=${DISTRO_ARCH}
+    if [ "${ISAR_CROSS_COMPILE}" = "1" ]; then
+        build_arch=${HOST_ARCH}
+    fi
+    if [ "${PACKAGE_ARCH}" != "${build_arch}" ]; then
+        args="--crossbuild \
+            crossbuild-essential-${PACKAGE_ARCH}:${build_arch} \
+            dose-distcheck:${build_arch} \
+            libc-dev:${PACKAGE_ARCH} \
+            libstdc++-dev:${PACKAGE_ARCH} \
+        "
+    fi
+
+    args="${args} --extrarepo=${WORKDIR}/isar-apt/${DISTRO}-${DISTRO_ARCH}/apt/${DISTRO}"
+
+    if [ -n "${GNUPGHOME}" ]; then
+        export GNUPGHOME="${GNUPGHOME}"
+    else
+        export GNUPGHOME="${WORKDIR}/gpghome"
+    fi
+
+    if [ -n "${DEB_BUILD_PROFILES}" ]; then
+        export DEB_BUILD_PROFILES="${DEB_BUILD_PROFILES}"
+    fi
+
+    ${SCRIPTSDIR}/debrepo \
+        --workdir="${DEBREPO_WORKDIR}" \
+        --dscfile="${dscfile}" \
+        ${args}
+}
diff --git a/meta/conf/bitbake.conf b/meta/conf/bitbake.conf
index 0f35a7fe..3f94392d 100644
--- a/meta/conf/bitbake.conf
+++ b/meta/conf/bitbake.conf
@@ -67,6 +67,11 @@ SDKCHROOT_DIR = "${DEPLOY_DIR_SDKCHROOT}/${BPN}-${DISTRO}-${MACHINE}"
 CACHE = "${TMPDIR}/cache"
 KERNEL_FILE ?= "${@ 'vmlinux' if d.getVar('DISTRO_ARCH') in ['mipsel', 'riscv64', 'arm64'] else 'vmlinuz'}"
 
+# debrepo config
+DEBREPO_DIR = "${TOPDIR}/debrepo"
+DEBREPO_HOST_DIR = "${DEBREPO_DIR}/${HOST_DISTRO}-${HOST_ARCH}_${DISTRO}-${DISTRO_ARCH}"
+DEBREPO_TARGET_DIR = "${DEBREPO_DIR}/${DISTRO}-${DISTRO_ARCH}"
+
 MACHINEOVERRIDES ?= "${MACHINE}"
 DISTROOVERRIDES ?= "${DISTRO}"
 OVERRIDES = "${PACKAGE_ARCH}:${MACHINEOVERRIDES}:${DISTROOVERRIDES}:${BASE_DISTRO_CODENAME}::${BASE_DISTRO}:${ISAR_CHROOT_MODE}:forcevariable"
-- 
2.43.0

-- 
You received this message because you are subscribed to the Google Groups "isar-users" group.
To unsubscribe from this group and stop receiving emails from it, send an email to isar-users+unsubscribe@googlegroups.com.
To view this discussion visit https://groups.google.com/d/msgid/isar-users/20260727112812.2255297-3-akarpovich%40ilbers.de.