[PATCH] dpkg-base: Expand adjust_git to all git SRC_URIs

[Jan Kiszka <jan.kiszka@siemens.com>]

From: Jan Kiszka <jan.kiszka@siemens.com>

Make sure that not only the first git SRC_URI is adjusted in case a
package builds from multiple repos. That's a common case for modern
U-Boot (ATF, OP-TEE...).

Signed-off-by: Jan Kiszka <jan.kiszka@siemens.com>
---
 meta/classes/dpkg-base.bbclass | 36 +++++++++++++++++++++++++++++++-----
 1 file changed, 31 insertions(+), 5 deletions(-)

diff --git a/meta/classes/dpkg-base.bbclass b/meta/classes/dpkg-base.bbclass
index 0be1627..af9c984 100644
--- a/meta/classes/dpkg-base.bbclass
+++ b/meta/classes/dpkg-base.bbclass
@@ -10,11 +10,37 @@ inherit terminal
 
 DEPENDS ?= ""
 
-do_adjust_git() {
-    if [ -f ${S}/.git/objects/info/alternates ]; then
-        sed -i ${S}/.git/objects/info/alternates \
-            -e 's|${DL_DIR}|/downloads|'
-    fi
+python do_adjust_git() {
+    import subprocess
+
+    rootdir = d.getVar('WORKDIR', True)
+
+    for src_uri in (d.getVar("SRC_URI", True) or "").split():
+        try:
+            fetcher = bb.fetch2.Fetch([src_uri], d)
+            ud = fetcher.ud[src_uri]
+            if ud.type != 'git':
+                continue
+
+            subdir = ud.parm.get("subpath", "")
+            if subdir != "":
+                def_destsuffix = "%s/" % os.path.basename(subdir.rstrip('/'))
+            else:
+                def_destsuffix = "git/"
+
+            destsuffix = ud.parm.get("destsuffix", def_destsuffix)
+            destdir = ud.destdir = os.path.join(rootdir, destsuffix)
+
+            alternates = os.path.join(destdir, ".git/objects/info/alternates")
+
+            if os.path.exists(alternates):
+                cmd = ["sed", "-i", alternates, "-e",
+                       "s|{}|/downloads|".format(d.getVar("DL_DIR"))]
+                bb.note(' '.join(cmd))
+                if subprocess.call(cmd) != 0:
+                    bb.fatal("git alternates adjustment failed")
+        except bb.fetch2.BBFetchException as e:
+            raise bb.build.FuncFailed(e)
 }
 
 addtask adjust_git after do_unpack before do_patch
-- 
2.16.4


-- 
Siemens AG, Corporate Technology, CT RDA IOT SES-DE
Corporate Competence Center Embedded Linux