Re: [PATCH] meta/image: leave BUILD_ID and VARIANT in /etc/os-release

["Maxim Yu. Osipov" <mosipov@ilbers.de>]

On 06/28/2018 06:05 PM, Henning Schild wrote:
> This commit adds support for leaving a mark in the resulting image.
> That should allow you to tell what code you used to create it. By
> default "git describe" will be used on Isar itself to come up with a
> BUILD_ID. And the DESCRIPTION of the image will become the VARIANT.
> 
> see
> https://www.freedesktop.org/software/systemd/man/os-release.html

Applied to the 'next',

Thanks,
Maxim.

> Signed-off-by: Henning Schild <henning.schild@siemens.com>
> ---
>   meta-isar/recipes-core/images/isar-image-base.bb |  2 ++
>   meta/classes/image.bbclass                       | 27 ++++++++++++++++++++++++
>   meta/classes/isar-bootstrap-helper.bbclass       | 26 +++++++++++++++++++++++
>   3 files changed, 55 insertions(+)
> 
> diff --git a/meta-isar/recipes-core/images/isar-image-base.bb b/meta-isar/recipes-core/images/isar-image-base.bb
> index 6cdc6b2..c72bfdb 100644
> --- a/meta-isar/recipes-core/images/isar-image-base.bb
> +++ b/meta-isar/recipes-core/images/isar-image-base.bb
> @@ -24,6 +24,8 @@ IMAGE_TRANSIENT_PACKAGES += "isar-cfg-localepurge"
>   
>   WORKDIR = "${TMPDIR}/work/${DISTRO}-${DISTRO_ARCH}/${PN}"
>   
> +ISAR_GIT_RELEASE_PATH ?= "${LAYERDIR_isar}"
> +
>   do_rootfs[root_cleandirs] = "${IMAGE_ROOTFS} \
>                                ${IMAGE_ROOTFS}/isar-apt"
>   
> diff --git a/meta/classes/image.bbclass b/meta/classes/image.bbclass
> index 3bdcb2f..00040e5 100644
> --- a/meta/classes/image.bbclass
> +++ b/meta/classes/image.bbclass
> @@ -34,6 +34,25 @@ def get_rootfs_size(d):
>   
>       return base_size + rootfs_extra * 1024
>   
> +# we assume that one git commit can describe the whole image, so you should be
> +# using submodules, kas, or something like that
> +# set ISAR_GIT_RELEASE_PATH to that one "most significant" layer
> +# when not using git, override do_mark_rootfs
> +def get_build_id(d):
> +    import subprocess
> +    if (len(d.getVar("BBLAYERS", True).strip().split(' ')) != 2 and
> +        (d.getVar("ISAR_GIT_RELEASE_PATH", True) ==
> +         d.getVar("LAYERDIR_isar", True))):
> +        bb.warn('You are using external layers that will not be considered' +
> +                ' in the build_id. Considder setting ISAR_GIT_RELEASE_PATH.')
> +    base = ["git", "-C", d.getVar("ISAR_GIT_RELEASE_PATH", True)]
> +    if (0 == subprocess.call(base + ["rev-parse"])):
> +        v = subprocess.check_output(base +
> +                                    ["describe", "--long", "--dirty",
> +                                     "--always"], universal_newlines=True)
> +        return v.rstrip()
> +    return ""
> +
>   python set_image_size () {
>       rootfs_size = get_rootfs_size(d)
>       d.setVar('ROOTFS_SIZE', str(rootfs_size))
> @@ -56,6 +75,14 @@ do_rootfs() {
>   addtask rootfs before do_build after do_unpack
>   do_rootfs[deptask] = "do_deploy_deb"
>   
> +do_mark_rootfs() {
> +    update_etc_os_release \
> +        --build-id "${@get_build_id(d)}" --variant "${DESCRIPTION}" \
> +        "${IMAGE_ROOTFS}"
> +}
> +
> +addtask mark_rootfs before do_copy_boot_files after do_rootfs
> +
>   do_copy_boot_files() {
>       KERNEL_IMAGE=${@get_image_name(d, 'vmlinuz')[1]}
>       if [ -n "${KERNEL_IMAGE}" ]; then
> diff --git a/meta/classes/isar-bootstrap-helper.bbclass b/meta/classes/isar-bootstrap-helper.bbclass
> index 3c10fc7..f375853 100644
> --- a/meta/classes/isar-bootstrap-helper.bbclass
> +++ b/meta/classes/isar-bootstrap-helper.bbclass
> @@ -14,6 +14,32 @@ def reverse_bb_array(d, varname):
>       array = reversed(array.split())
>       return " ".join(i for i in array)
>   
> +update_etc_os_release() {
> +    OS_RELEASE_BUILD_ID=""
> +    OS_RELEASE_VARIANT=""
> +    while true; do
> +        case "$1" in
> +	--build-id) OS_RELEASE_BUILD_ID=$2; shift ;;
> +	--variant) OS_RELEASE_VARIANT=$2; shift ;;
> +        -*) bbfatal "$0: invalid option specified: $1" ;;
> +        *) break ;;
> +        esac
> +        shift
> +    done
> +    ROOTFSDIR="$1"
> +
> +    if [ -n "${OS_RELEASE_BUILD_ID}" ]; then
> +        sudo sed -i '/^BUILD_ID=.*/d' ${ROOTFSDIR}/etc/os-release
> +        echo "BUILD_ID=\"${OS_RELEASE_BUILD_ID}\"" | \
> +            sudo tee -a ${ROOTFSDIR}/etc/os-release
> +    fi
> +    if [ -n "${OS_RELEASE_VARIANT}" ]; then
> +        sudo sed -i '/^VARIANT=.*/d' ${ROOTFSDIR}/etc/os-release
> +        echo "VARIANT=\"${OS_RELEASE_VARIANT}\"" | \
> +            sudo tee -a ${ROOTFSDIR}/etc/os-release
> +    fi
> +}
> +
>   setup_root_file_system() {
>       CLEAN=""
>       FSTAB=""
> 


-- 
Maxim Osipov
ilbers GmbH
Maria-Merian-Str. 8
85521 Ottobrunn
Germany
+49 (151) 6517 6917
mosipov@ilbers.de
http://ilbers.de/
Commercial register Munich, HRB 214197
General Manager: Baurzhan Ismagulov