[PATCH v2 5/8] Provide include file for easy custom kernel builds

[Jan Kiszka <jan.kiszka@siemens.com>]

From: Jan Kiszka <jan.kiszka@siemens.com>

With this include file, it becomes almost trivial to replace the distro
kernel with a custom build. You just need to include linux-custom.inc,
specify the source URI, define via S where the source is unpacked to and
provide a defconfig. To switch to a custom kernel recipe,
PREFERRED_PROVIDER_virtual/kernel has to be adjusted in local.conf or
the distro conf.

The approach works internally by first running "make deb-pkg" on the
kernel and the repackages the output to make the binary linux-image and
linux-header debs act as replacement of their distro packages. This
results in a suboptimal technical implementation which may eventually be
replaced by an isar-implemented deb-pkg build process. However, this is
not expected to affect the user-visible interface of this include file.

Signed-off-by: Jan Kiszka <jan.kiszka@siemens.com>
---
 meta/recipes-kernel/linux/linux-custom.inc | 98 ++++++++++++++++++++++++++++++
 1 file changed, 98 insertions(+)
 create mode 100644 meta/recipes-kernel/linux/linux-custom.inc

diff --git a/meta/recipes-kernel/linux/linux-custom.inc b/meta/recipes-kernel/linux/linux-custom.inc
new file mode 100644
index 0000000..feb96a1
--- /dev/null
+++ b/meta/recipes-kernel/linux/linux-custom.inc
@@ -0,0 +1,98 @@
+# Custom kernel recipe include
+#
+# This software is a part of ISAR.
+# Copyright (c) Siemens AG, 2018
+#
+# SPDX-License-Identifier: MIT
+
+DESCRIPTION ?= "Custom kernel"
+PROVIDES = "virtual/kernel"
+
+inherit dpkg-base
+
+KERNEL_DEBIAN_DEPENDS = "initramfs-tools | linux-initramfs-tool, kmod, linux-base (>= 4.3~)"
+KERNEL_HEADERS_DEBIAN_DEPENDS = "libc6, libssl1.1, gcc"
+KBUILD_DEPENDS = "libssl-dev libelf-dev bc"
+
+REPACK_DIR = "${PP}/repack"
+REPACK_LINUX_IMAGE_DIR = "${REPACK_DIR}/linux-image"
+REPACK_LINUX_HEADERS_DIR = "${REPACK_DIR}/linux-headers"
+
+dpkg_runbuild() {
+	E="${@ bb.utils.export_proxies(d)}"
+	sudo -E chroot ${BUILDCHROOT_DIR} sh -c '
+		set -e
+
+		apt-get install -y -o Debug::pkgProblemResolver=yes \
+			--no-install-recommends ${KBUILD_DEPENDS}
+
+		cd ${PP}/${S}
+		cp ../defconfig .config
+		make olddefconfig
+
+		make -j ${@bb.utils.cpu_count() * 2} deb-pkg
+
+		rm -rf ${REPACK_DIR}
+		mkdir -p ${REPACK_DIR}
+		mkdir -p ${REPACK_LINUX_IMAGE_DIR}
+		mkdir -p ${REPACK_LINUX_HEADERS_DIR}
+
+		cd ${PP}
+		tar xzf linux-${PV}_${PV}-1.debian.tar.gz -C ${REPACK_DIR}
+		dpkg-deb -R linux-image-${PV}_${PV}-1_${KERNEL_ARCH}.deb \
+			${REPACK_LINUX_IMAGE_DIR}
+		dpkg-deb -R linux-headers-${PV}_${PV}-1_${KERNEL_ARCH}.deb \
+			${REPACK_LINUX_HEADERS_DIR}
+
+		dpkg-gencontrol -crepack/debian/control \
+			-lrepack/debian/changelog \
+			-frepack/debian/files \
+			-plinux-image-${PV} \
+			-P${REPACK_LINUX_IMAGE_DIR} \
+			-DPackage="linux-image-${KERNEL_ARCH}" \
+			-DSection=kernel \
+			-DPriority=required \
+			-DProvides="${PN}" \
+			-DDepends="${KERNEL_DEBIAN_DEPENDS}"
+
+		# Add Debian-like link installation to postinst
+		touch ${REPACK_LINUX_IMAGE_DIR}/lib/modules/${PV}/.fresh-install
+		sed -i ${REPACK_LINUX_IMAGE_DIR}/DEBIAN/postinst \
+		    -e "/^set -e$/a\\
+\\
+if [ -f /lib/modules/${PV}/.fresh-install ]; then\\
+	change=install\\
+else\\
+	change=upgrade\\
+fi\\
+linux-update-symlinks \$change ${PV} /boot/vmlinuz-${PV}\\
+rm -f /lib/modules/${PV}/.fresh-install"
+
+		# Add Debian-like link removal to postrm
+		sed -i ${REPACK_LINUX_IMAGE_DIR}/DEBIAN/postrm \
+		    -e "/^set -e$/a\\
+\\
+rm -f /lib/modules/${PV}/.fresh-install\\
+\\
+if [ \"\$1\" != upgrade ] && command -v linux-update-symlinks >/dev/null; then\\
+	linux-update-symlinks remove ${PV}  /boot/vmlinuz-${PV}\\
+fi"
+
+		dpkg-gencontrol -crepack/debian/control \
+			-lrepack/debian/changelog \
+			-frepack/debian/files \
+			-plinux-headers-${PV} \
+			-P${REPACK_LINUX_HEADERS_DIR} \
+			-Vkernel:debarch="${KERNEL_ARCH}" \
+			-DPackage="linux-headers-${KERNEL_ARCH}" \
+			-DSection=kernel \
+			-DDepends="${KERNEL_HEADERS_DEBIAN_DEPENDS}"
+
+		dpkg-deb -b ${REPACK_LINUX_IMAGE_DIR} \
+			linux-image-${KERNEL_ARCH}_${PV}-1_${KERNEL_ARCH}.deb
+		rm -f linux-image-${PV}_${PV}-1_${KERNEL_ARCH}.deb
+		dpkg-deb -b ${REPACK_LINUX_HEADERS_DIR} \
+			linux-headers-${KERNEL_ARCH}_${PV}-1_${KERNEL_ARCH}.deb
+		rm -f linux-headers-${PV}_${PV}-1_${KERNEL_ARCH}.deb
+	'
+}
-- 
2.13.6