#
# CIP Core, generic profile
#
# Copyright (c) Siemens AG, 2022-2023
#
# Authors:
#  Sven Schultschik <sven.schultschik@siemens.com>
#  Jan Kiszka <jan.kiszka@siemens.com>
#
# SPDX-License-Identifier: MIT
#

HOMEPAGE = "https://github.com/tianocore/edk2"
MAINTAINER = "Sven Schultschik <sven.schultschik@siemens.com>"

inherit dpkg

SRC_URI = " \
    git://github.com/tianocore/edk2.git;protocol=https;branch=${SRC_BRANCH_EDK2};name=edk2;destsuffix=${S}/edk2 \
    git://github.com/tianocore/edk2-platforms.git;protocol=https;branch=${SRC_BRANCH_EDK2_PLAT};name=edk2-platforms;destsuffix=${S}/edk2-platforms \
    git://github.com/google/brotli;protocol=https;branch=${SRC_BRANCH_BROTLI};name=brotli;destsuffix=${S}/brotli \
    git://github.com/openssl/openssl;protocol=https;branch=${SRC_BRANCH_OPENSSL};name=openssl;destsuffix=${S}/openssl \
    file://rules.tmpl \
    "

PV = "202302"

SRC_BRANCH_EDK2 = "master"
#SRCREV_edk2 = " edk2-stable202302"
SRCREV_edk2 = "f80f052277c88a67c55e107b550f504eeea947d3"

SRC_BRANCH_EDK2_PLAT = "master"
# revision closest to edk2 release
SRCREV_edk2-platforms = "4ad557e494d8055f5ea16009d6e565cace6571d6"

SRC_BRANCH_BROTLI = "master"
# according to edk2 submodules
SRCREV_brotli = "f4153a09f87cbb9c826d8fc12c74642bb2d879ea"

SRC_BRANCH_OPENSSL = "OpenSSL_1_1_1-stable"
#SRCREV_openssl = "OpenSSL_1_1_1s"
SRCREV_openssl = "129058165d195e43a0ad10111b0c2e29bdf65980"

S = "${WORKDIR}/git"

DEBIAN_BUILD_DEPENDS = "bash, python3:native, dh-python, uuid-dev:native"

TEMPLATE_FILES = "rules.tmpl"


do_prepare_build() {
    deb_debianize

    rm -rf ${S}/edk2/BaseTools/Source/C/BrotliCompress/brotli
    ln -s ../../../../../brotli ${S}/edk2/BaseTools/Source/C/BrotliCompress/brotli

    rm -rf ${S}/edk2/MdeModulePkg/Library/BrotliCustomDecompressLib/brotli
    ln -s ../../../../brotli ${S}/edk2/MdeModulePkg/Library/BrotliCustomDecompressLib/brotli

    rm -rf ${S}/edk2/CryptoPkg/Library/OpensslLib/openssl
    ln -s ../../../../openssl ${S}/edk2/CryptoPkg/Library/OpensslLib/openssl

    echo "Build/MmStandaloneRpmb/RELEASE_GCC49/FV/BL32_AP_MM.fd /usr/lib/edk2/" > \
        ${S}/debian/edk2-standalonemm-rpmb.install
}