Re: [PATCH 2/6] Add clean and cleanall tasks

[Alexander Smirnov <asmirnov@ilbers.de>]

On 02/12/2018 10:59 AM, Jan Kiszka wrote:
> From: Jan Kiszka <jan.kiszka@siemens.com>
> 
> Derived from OE, this adds clean and cleanall tasks for Isar. The clean
> task comes with CLEANFUNCS hook, we just run them prior to cleaning the
> WORKDIR. This is used by dpkg-base to remove all packages from isar-apt
> that the build may have deployed.
> 
> As we are at it, also do a repo clean prior to deploying a package -
> just in case something triggers a partial rebuild without prior
> cleaning...
> 

Very good! :-)

I think, we also should erase the package's "PROVIDES" from buildchroot 
(like libhello-dev). This could be implemented later in next series.

Alex

> Signed-off-by: Jan Kiszka <jan.kiszka@siemens.com>
> ---
>   meta/classes/base.bbclass      | 35 ++++++++++++++++++++++++++++++++++-
>   meta/classes/dpkg-base.bbclass | 14 ++++++++++++++
>   2 files changed, 48 insertions(+), 1 deletion(-)
> 
> diff --git a/meta/classes/base.bbclass b/meta/classes/base.bbclass
> index 0fa27db..b0e174e 100644
> --- a/meta/classes/base.bbclass
> +++ b/meta/classes/base.bbclass
> @@ -110,4 +110,37 @@ python base_do_build () {
>       bb.note("Try running the 'listtasks' task against a .bb to see what tasks are defined.")
>   }
>   
> -EXPORT_FUNCTIONS do_clean do_mrproper do_build
> +EXPORT_FUNCTIONS do_build
> +
> +CLEANFUNCS ?= ""
> +
> +# Derived from OpenEmbedded Core: meta/classes/utility-tasks.bbclass
> +addtask clean
> +do_clean[nostamp] = "1"
> +python do_clean() {
> +    import subprocess
> +
> +    for f in (d.getVar('CLEANFUNCS', True) or '').split():
> +        bb.build.exec_func(f, d)
> +
> +    dir = d.expand("${WORKDIR}")
> +    subprocess.call('sudo rm -rf ' + dir, shell=True)
> +
> +    dir = "%s.*" % bb.data.expand(d.getVar('STAMP', False), d)
> +    subprocess.call('sudo rm -rf ' + dir, shell=True)
> +}
> +
> +# Derived from OpenEmbedded Core: meta/classes/base.bbclass
> +addtask cleanall after do_clean
> +do_cleanall[nostamp] = "1"
> +python do_cleanall() {
> +    src_uri = (d.getVar('SRC_URI', True) or "").split()
> +    if len(src_uri) == 0:
> +        return
> +
> +    try:
> +        fetcher = bb.fetch2.Fetch(src_uri, d)
> +        fetcher.clean()
> +    except bb.fetch2.BBFetchException as e:
> +        bb.fatal(str(e))
> +}
> diff --git a/meta/classes/dpkg-base.bbclass b/meta/classes/dpkg-base.bbclass
> index 69c8ad5..a45fbce 100644
> --- a/meta/classes/dpkg-base.bbclass
> +++ b/meta/classes/dpkg-base.bbclass
> @@ -31,8 +31,22 @@ do_build() {
>       sudo rmdir ${BUILDROOT} 2>/dev/null || true
>   }
>   
> +CLEANFUNCS += "repo_clean"
> +
> +repo_clean() {
> +    PACKAGES=$(cd ${WORKDIR}; ls *.deb | sed 's/\([^_]*\).*/\1/')
> +    if [ -n "${PACKAGES}" ]; then
> +        reprepro -b ${DEPLOY_DIR_APT}/${DISTRO} \
> +                 --dbdir ${DEPLOY_DIR_DB}/${DISTRO} \
> +                 -C main \
> +                 remove ${DEBDISTRONAME} \
> +                 ${PACKAGES}
> +    fi
> +}
> +
>   # Install package to Isar-apt
>   do_deploy_deb() {
> +    repo_clean
>       reprepro -b ${DEPLOY_DIR_APT}/${DISTRO} \
>                --dbdir ${DEPLOY_DIR_DB}/${DISTRO} \
>                -C main \
>