[PATCH 1/5] meta: Factor out buildchroot class

[Jan Kiszka <jan.kiszka@siemens.com>]

From: Jan Kiszka <jan.kiszka@siemens.com>

This makes commonly useful things like BUILDCHROOT_DIR determination as
well as mounting into the builchroot available for reuse outside of the
dpkg scope.

Signed-off-by: Jan Kiszka <jan.kiszka@siemens.com>
---
 meta/classes/buildchroot.bbclass | 33 +++++++++++++++++++++++++++++++++
 meta/classes/dpkg-base.bbclass   | 33 ++++++---------------------------
 2 files changed, 39 insertions(+), 27 deletions(-)
 create mode 100644 meta/classes/buildchroot.bbclass

diff --git a/meta/classes/buildchroot.bbclass b/meta/classes/buildchroot.bbclass
new file mode 100644
index 0000000..f67335e
--- /dev/null
+++ b/meta/classes/buildchroot.bbclass
@@ -0,0 +1,33 @@
+# This software is a part of ISAR.
+# Copyright (C) 2018 Siemens AG
+#
+# SPDX-License-Identifier: MIT
+
+ISAR_CROSS_COMPILE ??= "0"
+
+# Add dependency from the correct buildchroot: host or target
+python __anonymous() {
+    mode = d.getVar('ISAR_CROSS_COMPILE', True)
+    if mode == "0":
+        dep = "buildchroot-target:do_build"
+        rootfs = d.getVar('BUILDCHROOT_TARGET_DIR', True)
+    else:
+        dep = "buildchroot-host:do_build"
+        rootfs = d.getVar('BUILDCHROOT_HOST_DIR', True)
+
+    d.setVarFlag('do_prepare_build', 'depends', dep)
+    d.setVar('BUILDCHROOT_DIR', rootfs)
+}
+
+MOUNT_LOCKFILE = "${BUILDCHROOT_DIR}/mount.lock"
+
+buildchroot_do_mounts() {
+    sudo flock ${MOUNT_LOCKFILE} -c ' \
+        set -e
+        if ! grep -q ${BUILDCHROOT_DIR}/isar-apt /proc/mounts; then
+            mount --bind ${DEPLOY_DIR_APT}/${DISTRO} ${BUILDCHROOT_DIR}/isar-apt
+            mount --bind ${DL_DIR} ${BUILDCHROOT_DIR}/downloads
+            mount -t devtmpfs -o mode=0755,nosuid devtmpfs ${BUILDCHROOT_DIR}/dev
+            mount -t proc none ${BUILDCHROOT_DIR}/proc
+        fi'
+}
diff --git a/meta/classes/dpkg-base.bbclass b/meta/classes/dpkg-base.bbclass
index a2d2ff0..edd111b 100644
--- a/meta/classes/dpkg-base.bbclass
+++ b/meta/classes/dpkg-base.bbclass
@@ -1,24 +1,12 @@
 # This software is a part of ISAR.
-# Copyright (C) 2017 Siemens AG
+# Copyright (C) 2017-2018 Siemens AG
+#
+# SPDX-License-Identifier: MIT
 
-ISAR_CROSS_COMPILE ??= "0"
+inherit buildchroot
 
 DEPENDS ?= ""
 
-# Add dependency from the correct buildchroot: host or target
-python __anonymous() {
-    mode = d.getVar('ISAR_CROSS_COMPILE', True)
-    if mode == "0":
-        dep = "buildchroot-target:do_build"
-        rootfs = d.getVar('BUILDCHROOT_TARGET_DIR', True)
-    else:
-        dep = "buildchroot-host:do_build"
-        rootfs = d.getVar('BUILDCHROOT_HOST_DIR', True)
-
-    d.setVarFlag('do_prepare_build', 'depends', dep)
-    d.setVar('BUILDCHROOT_DIR', rootfs)
-}
-
 do_adjust_git() {
     if [ -f ${S}/.git/objects/info/alternates ]; then
         sed -i ${S}/.git/objects/info/alternates \
@@ -45,7 +33,6 @@ def get_package_srcdir(d):
 PP = "/home/builder/${PN}"
 PPS ?= "${@get_package_srcdir(d)}"
 
-BUILDROOT = "${BUILDCHROOT_DIR}/${PP}"
 do_build[stamp-extra-info] = "${DISTRO}-${DISTRO_ARCH}"
 
 # Empty do_prepare_build() implementation, to be overwritten if needed
@@ -59,21 +46,13 @@ do_prepare_build[stamp-extra-info] = "${DISTRO}-${DISTRO_ARCH}"
 # deployed to isar-apt
 do_prepare_build[deptask] = "do_deploy_deb"
 
-MOUNT_LOCKFILE = "${BUILDCHROOT_DIR}/mount.lock"
+BUILDROOT = "${BUILDCHROOT_DIR}/${PP}"
 
-# Wrap the function dpkg_runbuild with the bind mount for buildroot
 dpkg_do_mounts() {
     mkdir -p ${BUILDROOT}
     sudo mount --bind ${WORKDIR} ${BUILDROOT}
 
-    sudo flock ${MOUNT_LOCKFILE} -c ' \
-        set -e
-        if ! grep -q ${BUILDCHROOT_DIR}/isar-apt /proc/mounts; then
-            mount --bind ${DEPLOY_DIR_APT}/${DISTRO} ${BUILDCHROOT_DIR}/isar-apt
-            mount --bind ${DL_DIR} ${BUILDCHROOT_DIR}/downloads
-            mount -t devtmpfs -o mode=0755,nosuid devtmpfs ${BUILDCHROOT_DIR}/dev
-            mount -t proc none ${BUILDCHROOT_DIR}/proc
-        fi'
+    buildchroot_do_mounts
 }
 
 dpkg_undo_mounts() {
-- 
2.16.4