[PATCH v6 12/27] Detect false sharing of recipes

[Jan Kiszka <jan.kiszka@siemens.com>]

From: Jan Kiszka <jan.kiszka@siemens.com>

When a task is run more than once per build, this indicates a bug,
usually (though not only) related to incorrect multiconfig use. Such
bugs are hard to find in practice, so they could benefit from some
tooling.

This adds a very simple but effective check for such re-run scenarios
by putting a "once.<taskname>" stamp file into each workdir during a
build. If such a file already exists, an error is thrown. The workdirs
are purged after the parsing phase on the beginning of each build so
that no false positives are raised. The task stamp is also deleted after
failures so that no (serialized) retries can cause warnings.

Signed-off-by: Jan Kiszka <jan.kiszka@siemens.com>
---

Changes in v6:
 - avoid warnings after build failures of shared tasks
 - code refactoring

 meta/classes/isar-events.bbclass | 34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

diff --git a/meta/classes/isar-events.bbclass b/meta/classes/isar-events.bbclass
index 62eb25d..cad1d57 100644
--- a/meta/classes/isar-events.bbclass
+++ b/meta/classes/isar-events.bbclass
@@ -4,6 +4,40 @@
 # Copyright (C) 2015-2017 ilbers GmbH
 # Copyright (c) Siemens AG, 2018
 
+addhandler parse_completed
+
+python parse_completed() {
+    bb.utils.remove(d.getVar('TMPDIR') + "/work/*/*/*/temp/once.*")
+}
+parse_completed[eventmask] = "bb.event.ParseCompleted"
+
+def task_once_stamp(d):
+    return "{temp}/once.{task}".format(temp=d.getVar('T'),
+                                       task=d.getVar('BB_RUNTASK'))
+
+addhandler task_started
+
+python task_started() {
+    try:
+        f = open(task_once_stamp(d), "x")
+        f.close()
+    except FileExistsError:
+        bb.error("Detect multiple executions of %s in %s" %
+                 (d.getVar('BB_RUNTASK'), d.getVar('WORKDIR')))
+        bb.error("Rerun a clean build with empty STAMPCLEAN " \
+                 "and compare the sigdata files")
+}
+task_started[eventmask] = "bb.build.TaskStarted"
+
+addhandler task_failed
+
+python task_failed() {
+    # Avoid false positives if a second target depends on this task and retries
+    # the execution after the first failure.
+    os.remove(task_once_stamp(d))
+}
+task_failed[eventmask] = "bb.build.TaskFailed"
+
 addhandler build_completed
 
 python build_completed() {
-- 
2.16.4