[PATCH 6/7] u-boot-script: Make truly generic

[Jan Kiszka <jan.kiszka@siemens.com>]

From: Jan Kiszka <jan.kiszka@siemens.com>

Now that rootfs-u-boot can generate the required config, we can remove
any config generation from this package. Makes things much simpler.

Signed-off-by: Jan Kiszka <jan.kiszka@siemens.com>
---
 meta-isar/conf/machine/bananapi.conf               |  2 +-
 meta-isar/conf/machine/de0-nano-soc.conf           |  2 +-
 .../recipes-bsp/u-boot-script/u-boot-script_1.0.bb | 81 ----------------------
 .../recipes-bsp/u-boot-script/u-boot-script_1.1.bb | 28 ++++++++
 4 files changed, 30 insertions(+), 83 deletions(-)
 delete mode 100644 meta/recipes-bsp/u-boot-script/u-boot-script_1.0.bb
 create mode 100644 meta/recipes-bsp/u-boot-script/u-boot-script_1.1.bb

diff --git a/meta-isar/conf/machine/bananapi.conf b/meta-isar/conf/machine/bananapi.conf
index 95876f1..7b380c1 100644
--- a/meta-isar/conf/machine/bananapi.conf
+++ b/meta-isar/conf/machine/bananapi.conf
@@ -10,7 +10,7 @@ KERNEL_NAME ?= "armmp"
 DISTRO_APT_SOURCES_append = " conf/distro/debian-stretch-backports.list"
 DISTRO_APT_PREFERENCES += "conf/multiconfig/preferences.bananapi.conf"
 
-IMAGE_INSTALL += "u-boot-script-${KERNEL_NAME}"
+IMAGE_INSTALL += "u-boot-script"
 
 IMAGE_TYPE ?= "wic-img"
 WKS_FILE ?= "bananapi"
diff --git a/meta-isar/conf/machine/de0-nano-soc.conf b/meta-isar/conf/machine/de0-nano-soc.conf
index 184da4a..63b2cfb 100644
--- a/meta-isar/conf/machine/de0-nano-soc.conf
+++ b/meta-isar/conf/machine/de0-nano-soc.conf
@@ -15,4 +15,4 @@ WKS_FILE ?= "de0-nano-soc"
 IMAGER_INSTALL += "u-boot-de0-nano-soc"
 IMAGER_BUILD_DEPS += "u-boot-de0-nano-soc"
 
-IMAGE_INSTALL += "u-boot-tools u-boot-script-${KERNEL_NAME}"
+IMAGE_INSTALL += "u-boot-tools u-boot-script"
diff --git a/meta/recipes-bsp/u-boot-script/u-boot-script_1.0.bb b/meta/recipes-bsp/u-boot-script/u-boot-script_1.0.bb
deleted file mode 100644
index a827c35..0000000
--- a/meta/recipes-bsp/u-boot-script/u-boot-script_1.0.bb
+++ /dev/null
@@ -1,81 +0,0 @@
-# Boot script generator for U-Boot
-#
-# This software is a part of ISAR.
-# Copyright (c) Siemens AG, 2018
-#
-# SPDX-License-Identifier: MIT
-
-inherit dpkg-raw
-inherit wks-file
-
-WKS_FULL_PATH = "${@get_wks_full_path(d)}"
-
-DESCRIPTION = "Boot script generator for U-Boot"
-
-PN .= "-${KERNEL_NAME}"
-
-SRC_URI = " \
-    file://update-u-boot-script \
-    file://u-boot-script \
-    file://zz-u-boot-script"
-
-DEBIAN_DEPENDS = "u-boot-tools, linux-image-${KERNEL_NAME}"
-
-# Extract the following information from the wks file and add it to the
-# packaged /etc/default/u-boot-script:
-#  - --append parameters from a bootloader entry
-#  - root partition number
-#  - disk name the root partition is located on
-
-init_config_from_wks() {
-	# Filter out the bootloader line, then grap the argument of --append.
-	# The argument may be quoted, respect that but remove the quotes prior
-	# to assigning the target variable. Will be re-added later.
-	KERNEL_ARGS=$(grep "^bootloader " $1 | \
-		      sed -e 's/.* --append[= ]\(".*"\|[^ $]*\).*/\1/' \
-			  -e 's/\"\(.*\)\"/\1/')
-
-	COUNT=0
-	while read COMMAND MNT OPTIONS; do
-		if [ "${COMMAND}" != part ] ||
-		   echo "${OPTIONS}" | grep -q "\--no-table"; then
-			continue
-		fi
-		COUNT=$(expr ${COUNT} + 1)
-		if [ "${MNT}" = "/" ]; then
-			ROOT_PARTITION=${COUNT}
-			break
-		fi
-	done < $1
-	if [ -n "${ROOT_PARTITION}" ]; then
-		# filter out parameter of --ondisk or --ondrive
-		ROOT=$(echo ${OPTIONS} | \
-		       sed 's/.*--on\(disk\|drive\)[ ]\+\([^ ]\+\) .*/\2/')
-		# anything found?
-		if [ "${ROOT}" != "${OPTIONS}" ]; then
-			# special case: append 'p' to mmcblkN
-			ROOT=$(echo ${ROOT} | sed 's/^\(mmcblk[0-9]\+\)/\1p/')
-
-			KERNEL_ARGS="\"root=/dev/${ROOT}${ROOT_PARTITION} ${KERNEL_ARGS}\""
-		fi
-	fi
-
-	sed -i -e 's|\(^ROOT_PARTITION=\).*|\1\"'"${ROOT_PARTITION}"'\"|' \
-	       -e 's|\(^KERNEL_ARGS=\).*|\1'"${KERNEL_ARGS}"'|' \
-		${WORKDIR}/u-boot-script
-}
-
-do_install() {
-	[ -n ${WKS_FULL_PATH} ] && init_config_from_wks "${WKS_FULL_PATH}"
-
-	sudo rm -rf ${D}/etc ${D}/usr
-
-	install -v -d ${D}/usr/sbin
-	install -v -m 755 ${WORKDIR}/update-u-boot-script ${D}/usr/sbin/
-
-	install -v -d ${D}/etc/default
-	install -v -m 644 ${WORKDIR}/u-boot-script ${D}/etc/default/
-
-	install -v -d ${D}/etc/kernel/postinst.d
-	install -v -m 755 ${WORKDIR}/zz-u-boot-script ${D}/etc/kernel/postinst.d
-}
diff --git a/meta/recipes-bsp/u-boot-script/u-boot-script_1.1.bb b/meta/recipes-bsp/u-boot-script/u-boot-script_1.1.bb
new file mode 100644
index 0000000..e07deee
--- /dev/null
+++ b/meta/recipes-bsp/u-boot-script/u-boot-script_1.1.bb
@@ -0,0 +1,28 @@
+# Boot script generator for U-Boot
+#
+# This software is a part of ISAR.
+# Copyright (c) Siemens AG, 2018
+#
+# SPDX-License-Identifier: MIT
+
+inherit dpkg-raw
+
+DESCRIPTION = "Boot script generator for U-Boot"
+
+SRC_URI = " \
+    file://update-u-boot-script \
+    file://u-boot-script \
+    file://zz-u-boot-script"
+
+DEBIAN_DEPENDS = "u-boot-tools, linux-image-${KERNEL_NAME}"
+
+do_install() {
+	install -v -d ${D}/usr/sbin
+	install -v -m 755 ${WORKDIR}/update-u-boot-script ${D}/usr/sbin/
+
+	install -v -d ${D}/etc/default
+	install -v -m 644 ${WORKDIR}/u-boot-script ${D}/etc/default/
+
+	install -v -d ${D}/etc/kernel/postinst.d
+	install -v -m 755 ${WORKDIR}/zz-u-boot-script ${D}/etc/kernel/postinst.d
+}
-- 
2.16.4